Excel-VBA操作文件四大方法之一（转）
Excel-VBA操作文件四大方法之一
https://www.cnblogs.com/top5/archive/2009/10/29/1591937.html
在我們日常使用Excel的時候，不僅會用到當前Excel文件的數據，還經常需要訪問其他的數據文件。這些數據文件可能是Excel文件、文本文 件或數據庫文件等。經常有朋友會問如何在vba代碼里操作這些數據文件？本文就系統地介紹一下在Excel中應用VBA操作數據文件的方法。
本文主要介紹四種常用的方法：
1、利用Excel對象來處理文件；
2、利用VBA文件處理語句來處理文件；
3、利用FileSystemObject對象來處理文件；
4、利用API函數來處理文件。
當然對于數據庫文件，還可以利用ADO＋SQL的方法操作，不過論壇已經有前輩詳細介紹過此類方法，本文就不再重復了。
一、利用Excel對象來處理文件
利用Excel對象自帶的方法來操作文件是最方便，也是最簡單的。
我們主要利用Workbooks集合和Workbook對象的方法來操作文件。
1、打開Excel文件
我們可以用Workbooks.Open方法打開一個Excel工作簿。
Workbooks.Open(FileName, UpdateLinks, ReadOnly, Format, Password, WriteResPassword, IgnoreReadOnlyRecommended, Origin, Delimiter, Editable, Notify, Converter, AddToMru, Local, CorruptLoad)
其中FileName是必選的參數，表示要打開的工作簿名，如果沒有指定路徑，則代表當前路徑。另外14個是可選參數，除了密碼參數，其他的一般很少用。具體的含義可以參看VBA的幫助。
例：
Workbooks.Open “F:\test.xls”
可以打開F盤的test.xls文件。
2、打開文本文件
使用Open方法也可以打開文本文件，但建議使用OpenText方法。此方法是載入一個文本文件，并將其作為包含單個工作表的工作簿進行分列處理，然后在此工作表中放入經過分列處理的文本文件數據。完整語法如下：
Workbooks.OpenText(FileName, Origin, StartRow, DataType, TextQualifier, ConsecutiveDelimiter, Tab, Semicolon, Comma, Space, Other, OtherChar, FieldInfo, TextVisualLayout, DecimalSeparator, ThousandsSeparator, TrailingMinusNumbers, Local)
關于以上參數的具體含義可以參看VBA的幫助，這里就不重復了。在實際的編程中，一般無需對這些復雜的參數進行處理。可以通過錄制宏來得到打開一個 文本文件的VBA代碼。具體方法就是選擇“文件——打開”，然后選擇打開文本文件，就會出現文本導入向導，一步一步執行完，直到文本打開后，停止錄制。
以下是錄制宏得到的代碼:
Sub Macro1()
’
’ Macro1 Macro
’ 宏由 MC SYSTEM 錄制，時間: 2007-3-29
’
’
Workbooks.OpenText Filename:=“F:\CallWindowProc.txt”, Origin:=xlWindows, _
StartRow:=1, DataType:=xlDelimited, TextQualifier:=xlDoubleQuote, _
ConsecutiveDelimiter:=False, Tab:=True, Semicolon:=False, Comma:=False _
, Space:=False, Other:=False, FieldInfo:=Array(1, 1), _
TrailingMinusNumbers:=True
End Sub
在實際編程中只要做相應的修改就可以使用了。
3、打開其他文件
利用Excel對象還可以打開XML文件和一些數據庫（如Access）文件，對應XML文件，需要Excel2003以上的版本。
OpenXML方法的語法如下：
Workbooks.OpenXML(Filename, Stylesheets, LoadOption)
FileName String 類型，必需。要打開的文件名。
Stylesheets Variant 類型，可選。單個值或值的數組，用于指定要應用哪些 XSL 轉換 (XSLT) 樣式表處理指令。
LoadOption Variant 類型，轉換。指定 Excel 打開 XML 數據文件的方式。可為 XlXmlLoadOption 常量之一。
XlXmlLoadOption 可為以下 XlXmlLoadOption 常量之一：
xlXmlLoadImportToList 將 XML 數據文件的內容置于 XML 列表中。
xlXmlLoadMapXml 在“XML 結構”任務窗格中顯示 XML 數據文件的架構。
xlXmlLoadOpenXml 打開 XML 數據文件。文件的內容將展開。
xlXmlLoadPromptUser 提示用戶選擇打開文件的方式。
示例
下面的代碼打開了 XML 數據文件“customers.xml”并在 XML 列表中顯示了此文件的內容。
Sub UseOpenXML()
Application.Workbooks.OpenXML _
Filename:=“customers.xml”, _
LoadOption:=xlXmlLoadImportToList
End Sub
OpenDatabase 方法語法如下：
Workbooks.OpenDatabase(FileName, CommandText, CommandType, BackgroundQuery, ImportDataAs)
FileName String 類型，必需。連接字符串。
CommandText Variant 類型，可選。查詢的命令文本。
CommandType Variant 類型，可選。查詢的命令類型。以下是可用的命令類型：Default、SQL 和 Table。
BackgroundQuery Variant 類型，可選。查詢的背景。
ImportDataAs Variant 類型，可選。確定查詢的格式。
示例
本示例中，Excel 打開了“northwind.mdb”文件。
Sub OpenDatabase()
Workbooks.OpenDatabase FileName:=“C:\northwind.mdb”
End Sub
4、保存文件
文件的保存使用Workbook對象的Save或SaveAs方法。
Save方法使用簡單，語法為
expression.Save，expression是某個Workbook對象。
如：ActiveWorkbook.Save
即保存當前活動工作簿。
如果是第一次保存工作簿或要另存為，請使用 SaveAs 方法為該文件指定文件名。
其語法為：
expression.SaveAs(FileName, FileFormat, Password, WriteResPassword, ReadOnlyRecommended, CreateBackup, AccessMode, ConflictResolution, AddToMru, TextCodepage, TextVisualLayout, Local)
具體參數含義可參看VBA幫助，使用都比較簡單。
示例
本示例新建一個工作簿，提示用戶輸入文件名，然后保存該工作簿。
Set NewBook = Workbooks.Add
Do
fName = Application.GetSaveAsFilename
Loop Until fName <> False
NewBook.SaveAs Filename:=fName
Application.GetSaveAsFilename為調出標準的“另存為”對話框，獲取用戶文件名，但并不真正保存任何文件，然后使用代碼保存文件。還有Application.GetOpenFileName可以調出標準的“打開”對話框。
5、關閉文件
關閉文件可以使用Workbooks集合或Workbook對象的 Close 方法。前者是關閉所有打開的工作簿，后者關閉特定的工作簿。
Workbook對象的 Close 方法語法為：
expression.Close(SaveChanges, Filename, RouteWorkbook)
SaveChanges參數表示是否保存更改，對許多不需要更改的操作，可設置為False以免彈出保存更改提示的對話框。
FileName 可選。以此文件名保存所做的更改。
RouteWorkbook 可選。如果指定工作簿不需要傳送給下一個收件人（沒有傳送名單或已經傳送），則忽略該參數。
示例
本示例關閉 Book1.xls，并放棄所有對此工作簿的更改。
Workbooks(“BOOK1.XLS”).Close SaveChanges:=False
本示例關閉所有打開的工作簿。如果某個打開的工作簿有改變，Microsoft Excel 將顯示詢問是否保存更改的對話框和相應提示。
Workbooks.Close
6、綜合實例
假如F盤有一個Excel文件test.xls，現在有另一個Excel文件要訪問test.xls的數據，我們來看用VBA代碼如何操作。代碼如下：
Public Sub test()
Application.ScreenUpdating = False
Workbooks.Open “f:\test.xls”
ThisWorkbook.Sheets(1).Range(“b1”) = ActiveWorkbook.Sheets(1).Range(“a2”)
ActiveWorkbook.Close
Application.ScreenUpdating = True
End Sub
首先關閉屏幕刷新，是為了防止test.xls在打開時被看見(有時候還是看的見）。打開后，見test.xls的Sheet1的單元格A2中的值賦給當前工作簿的Sheet1的單元格B2，然后關閉test.xls。
當要打開的工作簿不確定的時候，可以通過調用打開對話框來讓用戶自己選擇。
可改為如下：
Public Sub test()
Application.ScreenUpdating = False
Dim Filename as String
Filename = Application.GetOpenFileName
Workbooks.Open Filename
ThisWorkbook.Sheets(1).Range(“b1”) = ActiveWorkbook.Sheets(1).Range(“a2”)
ActiveWorkbook.Close
Application.ScreenUpdating = True
End Sub
7、總結
利用Excel對象的方法進行文件操作是最簡單，也是最方便的，適合初學者。對于Excel文件格式，如果我們僅僅是讀取其表格中的內容，這種方法也是首選。對于文本文件的操作，使用第二種方法比較方便，若要將文本轉換成表格，那么使用此方法也是合適的。
如何在d:\test.xls已打開的情況下不讓以下的語句再去創建一個test.xls的實例(雖然它標識為只讀),
并給出文件已打開的提示.
先做一個判斷！判斷該工作簿是否打開了？
例如：
Set xlexcel = CreateObject(“excel.application”)
dim wb as object
set wb = xlexcel.workbooks(“test.xls”)
if wb is nothing then
msgbox “工作簿未打開！”
xlexcel.Workbooks.Open “d:\test.xls”
xlexcel.Visible = True
end if
Excel-VBA操作文件四大方法之二
二、利用VBA文件處理語句來處理文件
VBA包含了許多用于文件操作的語句和函數，可以滿足絕大多數情況下的文件操作要求。下面我們按照操作目的進行一一介紹。
（一）文件處理
1.Name 語句
語法：Name oldpathname As newpathname
功能：重命名一個文件、目錄、或文件夾，移動一個文件。
說明：在一個已打開的文件上使用 Name，將會產生錯誤。進行文件操作時，一定要注意錯誤處理。
示例：
On Error Resume Next '錯誤處理
Name “f:\TEST.xls” As “f:\TEST123.xls” '重命名
Name “f:\TEST.xls” As “f:\dll\TEST.xls” '移動文件
Name “f:\TEST.xls” As “d:\TEST123.xls” '跨驅動器移動并重命名文件
注意：Name不能移動一個目錄或文件夾。
2、FileCopy 語句
語法：FileCopy source, destination
功能：復制一個文件。
說明：如果對一個已打開的文件使用 FileCopy 語句，則會產生錯誤。
示例：
FileCopy “f:\TEST.xls”, “e:\TEST.xls” '從F盤復制TEST.xls到E盤
3、Kill 語句
語法：Kill pathname
功能：從磁盤中刪除文件。
說明：Kill 支持多字符 (*) 和單字符 (?) 的統配符來指定多重文件。如果使用 Kill 來刪除一個已打開的文件，則會產生錯誤。
示例：
Kill “f:\TEST.xls” ’刪除F盤的TEST.xls文件
Kill “f:*.xls” ’ 刪除F盤所有xls文件
4、GetAttr 函數
語法：GetAttr(pathname)
功能：獲取一個文件、目錄、或文件夾的屬性。返回一個 Integer值。
返回值
由 GetAttr 返回的值，是下面這些屬性值的總和：
常數 值 描述
vbNormal 0 常規
vbReadOnly 1 只讀
vbHidden 2 隱藏
vbSystem 4 系統文件
vbDirectory 16 目錄或文件夾
vbArchive 32 存檔文件
vbalias 64 指定的文件名是別名。只在Macintosh中可用。
說明：若要判斷是否設置了某個屬性，在 GetAttr 函數與想要得知的屬性值之間使用 And 運算符與逐位比較。如果所得的結果不為零，則表示設置了這個屬性值。
示例：
Debug.Print GetAttr(“F:\test.txt”) '若為存檔文件，在立即窗口可看到值為32
Debug.Print GetAttr(“F:\test.txt”) '將屬性—高級—可存檔文件的勾去掉后，值為0
為判斷一個文件是否只讀，可用下法:
Debug.Print GetAttr(“F:\test.txt”) And vbReadOnly
若值非零，說明時只讀的。
5、SetAttr 語句
語法：SetAttr pathname, attributes
功能：為一個文件設置屬性。
說明：如果想要給一個已打開的文件設置屬性，則會產生運行時錯誤。
示例：
SetAttr"F:\test.txt", vbHidden ’ 設置隱藏屬性。
SetAttr"F:\test.txt", vbHidden + vbReadOnly ’ 設置隱藏并只讀。
6、FileLen 函數
語法：FileLen(pathname)
功能：獲取一個文件的長度，單位是字節。
說明：當調用 FileLen 函數時，不需要打開文件，如果所指定的文件已經打開，則返回的值是這個文件在打開前的大小。
7、FileDateTime 函數
語法：FileDateTime(pathname)
功能：獲取一個文件被創建或最后修改后的日期和時間。
示例：
Debug.Print FileDateTime(“F:\TEST.xls”) '在立即窗口可看到2007-3-29 19:28:27
（二）目錄處理
1、CurDir 函數
語法：CurDir[(drive)]
功能：返回當前的路徑。
說明：drive 參數是可選的，它指定一個存在的驅動器。如果沒有指定驅動器，或 drive 是零長度字符串 ("")，則 CurDir 會返回當前驅動器的路徑。
示例：
Debug.Print CurDir ’ 返回“C:\Documents and Settings\yc\My Documents”。
Debug.Print CurDir(“C”) ’ 返回“C:\Documents and Settings\yc\My Documents”。
Debug.Print CurDir(“D”) ’ 返回“D:\”。
2、ChDir 語句
語法：ChDir path
功能：改變當前的目錄或文件夾。
說明：ChDir 語句改變缺省目錄位置，但不會改變缺省驅動器位置。缺省驅動器一般是C。
示例：
ChDir “D:\temp”
Debug.Print CurDir ’ 返回“C:\Documents and Settings\yc\My Documents”。
Debug.Print CurDir(“D”) ’ 返回“D:\temp”。
與上例比較，此時D盤的當前目錄已經變為“D:\temp”，但是缺省驅動器還是C。
3、ChDrive 語句
語法：ChDrive drive
功能：改變當前的驅動器。
說明：如果使用零長度的字符串 ("")，則當前的驅動器將不會改變。如果 drive 參數中有多個字符，則 ChDrive 只會使用首字母。
示例：
ChDrive “D”
ChDir “D:\temp”
Debug.Print CurDir ’ 返回“D:\temp”。
Debug.Print CurDir(“D”) ’ 返回“D:\temp”。
與上例比較，用CurDir返回的是“D:\temp”，當前驅動器已經變為D了。
4、Dir 函數
語法：Dir[(pathname[, attributes])]
兩個參數都是可選的，attributes表示文件屬性。
功能：返回一個文件名、目錄名或文件夾名稱，它必須與指定的模式或文件屬性、或磁盤卷標相匹配。
說明：在第一次調用 Dir 函數時，必須指定 pathname，否則會產生錯誤。如果也指定了文件屬性，那么就必須包括 pathname。
Dir 會返回匹配 pathname 的第一個文件名。若想得到其它匹配 pathname 的文件名，再一次調用 Dir，且不要使用參數。如果已沒有合乎條件的文件，則 Dir 會返回一個零長度字符串 ("")。一旦返回值為零長度字符串，并要再次調用 Dir 時，就必須指定 pathname，否則會產生錯誤。不必訪問到所有匹配當前 pathname 的文件名，就可以改變到一個新的 pathname 上。但是，不能以遞歸方式來調用 Dir 函數。以 vbDirectory 屬性來調用 Dir 不能連續地返回子目錄。
示例：
Debug.Print Dir(“F:\TEST.xls”) ’返回"TEST.xls"
Debug.Print Dir(“F:*.xls”) ’返回按條件第一個找到的文件名。
Debug.Print Dir(“F:*.txt”,vbReadOnly) ’返回第一個只讀的txt文件
以下過程可顯示C盤根目錄下的所有目錄.
Sub DirC()
MyPath = “c:”
MyName = dir(MyPath, vbDirectory) ’ 找尋第一項。
Do While MyName <> “” ’ 開始循環。
’ 跳過當前的目錄及上層目錄。
If MyName <> “.” And MyName <> “…” Then
’ 使用位比較來確定 MyName 代表一目錄。
If (GetAttr(MyPath & MyName) And vbDirectory) = vbDirectory Then
Debug.Print MyName ’ 如果它是一個目錄，將其名稱顯示出來。
End If
End If
MyName = dir ’ 查找下一個目錄。
Loop
End Sub
以下過程利用遞歸可以查找目錄和子目錄下的所有文件。
Public Sub FindFile(mPath As String, Optional sFile As String = “”)
On Error Resume Next
Dim s As String, sDir() As String
Dim i As Long, d As Long
If Right(mPath, 1) <> “” Then
mPath = mPath & “”
End If
'查找目錄下的文件
s = dir(mPath & sFile, vbArchive + vbDirectory + vbHidden + vbNormal + vbReadOnly + vbSystem)
Do While s <> “”
Debug.Print mPath & s
s = dir
Loop
'查找目錄下的子目錄
s = dir(mPath, vbArchive + vbDirectory + vbHidden + vbNormal + vbReadOnly + vbSystem)
Do While s <> “”
If s <> “.” And s <> “…” Then
If (GetAttr(mPath & s) And vbDirectory) = vbDirectory Then
d = d + 1
ReDim Preserve sDir(d)
sDir(d) = mPath & s
End If
End If
s = dir
Loop
'開始遞歸
For i = 1 To d
FindFile sDir(d) & “”
Next
End Sub
5、MkDir 語句
語法：MkDir path
功能：創建一個新的目錄或文件夾。
說明：path 可以包含驅動器。如果沒有指定驅動器，則 MkDir 會在當前驅動器上創建新的目錄或文件夾。
示例：
MkDir “MYDIR” '在當前目錄建立新的目錄或文件夾。
6、RmDir 語句
語法：RmDir path
功能：刪除一個存在的目錄或文件夾。
說明：如果想要使用 RmDir 來刪除一個含有文件的目錄或文件夾，則會發生錯誤。在試圖刪除目錄或文件夾之前，先使用 Kill 語句來刪除所有文件。
示例：
RmDir “MYDIR” ’ 將 MYDIR 刪除。
（三）處理文本文件
1、Open 語句
語法：Open pathname For mode [Access access] [lock] As [#]filenumber [Len=reclength]
其中access、lock、reclength為可選參數，一般不用。
mode 指定打開文件的方式。有5種：
Input：以輸入方式打開，即讀取方式。
Output：以輸出方式打開，即寫入方式。
Append：以追加方式打開，即添加內容到文件末尾。
Binary：以二進制方式打開。
Random：以隨機方式打開，如果未指定方式，則以 Random 方式打開文件。
filenumber 是一個有效的文件號，范圍在 1 到 511 之間。可以指定，也可使用 FreeFile 函數可得到下一個可用的文件號。
說明：如果 pathname 指定的文件不存在，那么，在用 Append、Binary、Output、或 Random 方式打開文件時，可以建立這一文件。
示例：
Open “F:\TEST.txt” For Input As #1 '以輸入方式打開
Open “F:\TEST.xls” For Binary As #1 '以二進制方式打開
2、Close 語句
語法：Close [filenumberlist]
filenumberlist 參數為一個或多個文件號，若省略 filenumberlist，則將關閉 Open 語句打開的所有活動文件。
說明：打開文件后，必須在使用完后關閉文件。
示例：
Dim I, FileName
For I = 1 To 3
FileName = “TEST” & I ’ 創建文件名。
Open FileName For Output As #I ’ 打開文件。
Print #I, “This is a test.” ’ 將字符串寫入文件。
Next I
Close ’ 將三個已打開的文件全部關閉。
3、Reset 語句
語法：Reset
功能：關閉所有用 Open 語句打開的磁盤文件。
說明：Reset 語句關閉 Open 語句打開的所有活動文件，并將文件緩沖區的所有內容寫入磁盤。
示例：
Dim FileNumber
For FileNumber = 1 To 5
Open “TEST” & FileNumber For Output As #FileNumber
Write #FileNumber, “Hello World” ’ 將數據寫入文件。
Next FileNumber
Reset ’ 關閉文件并將緩沖區內的數據寫到磁盤中。
4、FreeFile 函數
語法：FreeFile[(rangenumber)]
參數 rangenumber指定一個范圍，以便返回該范圍之內的下一個可用文件號。指定 0（缺省值）則返回一個介于 1 – 255 之間的文件號。指定 1 則返回一個介于 256 – 511 之間的文件號。
功能：提供一個尚未使用的文件號。
示例：
Dim fnum As Integer
fnum = FreeFile
Open “F:\TEST.txt” For Input As #fnum
Close #fnum
5、EOF 函數
語法：EOF(filenumber)
功能：返回一個 Integer，它包含 Boolean 值 True，表明已經到達為 Random 或順序 Input 打開的文件的結尾。
6、LOF 函數
語法：LOF(filenumber)
功能：返回一個 Long，表示用 Open 語句打開的文件的大小，該大小以字節為單位。
7、Loc 函數
語法：LOc(filenumber)
功能：返回一個 Long，在已打開的文件中指定當前讀/寫位置。
8、Input # 語句
語法：Input #filenumber, varlist
功能：從已打開的順序文件中讀出數據并將數據指定給變量。
說明：通常用 Write # 將 Input # 語句讀出的數據寫入文件。為了能夠用 Input # 語句將文件的數據正確讀入到變量中，在將數據寫入文件時，要使用 Write # 語句而不使用 Print # 語句。使用 Write # 語句可以確保將各個單獨的數據域正確分隔開。
示例：
本示例使用 Input # 語句將文件內的數據讀入兩個變量中。本示例假設 TESTFILE文件內含數行以 Write # 語句寫入的數據；也就是說，每一行數據中的字符串部分都是用雙引號括起來，而與數字用逗號隔開，例如，（“Hello”, 234）。
Dim MyString, MyNumber
Open “TESTFILE” For Input As #1 ’ 打開輸入文件。
Do While Not EOF(1) ’ 循環至文件尾。
Input #1, MyString, MyNumber ’ 將數據讀入兩個變量。
Debug.Print MyString, MyNumber ’ 在立即窗口中顯示數據。
Loop
Close #1 ’ 關閉文件。
9、Write # 語句
語法：Write #filenumber, [outputlist]
功能：將數據寫入順序文件。
說明：通常用 Input # 從文件讀出 Write # 寫入的數據。
如果省略 outputlist，并在 filenumber 之后加上一個逗號，則會將一個空白行打印到文件中。多個表達式之間可用空白、分號或逗號隔開。空白和分號等效。
用 Write # 將數據寫入文件時將遵循幾個通用的約定，使得無論什么區域都可用 Input # 讀出并正確解釋數據：
·在寫入數值數據時總使用句號作為十進制分隔符。
·對于 Boolean 類型的數據，或者打印 #TRUE# 或者打印 #FALSE#。無論在什么地區，都不將 True 和 False 這兩個關鍵字翻譯出來。
·使用通用的日期格式將 Date 類型的數據寫入文件中。當日期或時間的部件丟失或為零時，只將現有部分寫入文件中。
·如果 outputlist 的數據為 Empty，則不將任何數據寫入文件。但對 Null 數據，則要寫入 #NULL#。
·如果 outputlist 數據為 Null 數據，則將 #NULL# 寫入文件中。
·對于 Error 類型的數據，輸出看起來與 #ERROR errorcode# 一樣。無論在什么地區，都不將關鍵字 Error 翻譯出來。
與 Print # 語句不同，當要將數據寫入文件時，Write # 語句會在項目和用來標記字符串的引號之間插入逗號。沒有必要在列表中鍵入明確的分界符。Write # 語句在將 outputlist 中的最后一個字符寫入文件后會插入一個新行字符，即回車換行符，(Chr(13) + Chr(10))。
示例：
Open “F:\test.txt” For Output As #1 ’ 打開輸出文件。
Write #1, “Hello World”, 1234 ’ 寫入以逗號隔開的數據。
Write #1, ’ 寫入空白行。
Dim MyBool, MyDate, MyNull, MyError
’ 賦值 Boolean、Date、Null 及 Error 等。
MyBool = False : MyDate = #February 12, 1969# : MyNull = Null
MyError = CVErr(32767)
’ Boolean 數據以 #TRUE# 或 #FALSE# 的格式寫入。
’ 日期以通用日期格式寫入，例如：#1994-07-13# 代表
’ 1994 年 1 月 13 日。Null 數據以 #NULL# 格式寫入。
’ Error 數據以 #ERROR 錯誤代號# 的格式寫入。
Write #1, MyBool; " is a Boolean value"
Write #1, MyDate; " is a date"
Write #1, MyNull; " is a null value"
Write #1, MyError; " is an error value"
Close #1 ’ 關閉文件。
我們可以看到寫入的內容為：
“Hello World”,1234
#FALSE#," is a Boolean value"
#1969-02-12#," is a date"
#NULL#," is a null value"
#ERROR 32767#," is an error value"
10、Line Input # 語句
語法：Line Input #filenumber, varname
功能：從已打開的順序文件中讀出一行并將它分配給 String 變量。
說明：通常用 Print # 與 Line Input # 語句配合使用。
Line Input # 語句一次只從文件中讀出一個字符，直到遇到回車符 (Chr(13)) 或回車–換行符 (Chr(13) + Chr(10)) 為止。回車–換行符將被跳過，而不會被附加到字符串上。
示例：
Dim TextLine
Open “TESTFILE” For Input As #1 ’ 打開文件。
Do While Not EOF(1) ’ 循環至文件尾。
Line Input #1, TextLine ’ 讀入一行數據并將其賦予某變量。
Debug.Print TextLine ’ 在立即窗口中顯示數據。
Loop
Close #1 ’ 關閉文件。
11、Input 函數
語法：Input(number, [#]filenumber)
其中number 指定要返回的字符個數。
功能:返回 String，它包含以 Input 或 Binary 方式打開的文件中的字符。
說明：通常用 Print # 或 Put 將 Input 函數讀出的數據寫入文件。Input 函數只用于以 Input 或 Binary 方式打開的文件。
與 Input # 語句不同，Input 函數返回它所讀出的所有字符，包括逗號、回車符、空白列、換行符、引號和前導空格等。
示例：
Dim MyChar
Open “f:\test.txt” For Input As #1
Do While Not EOF(1) ’ 循環至文件尾。
MyChar = Input(1, #1) ’ 讀入一個字符。
Debug.Print MyChar ’ 顯示到立即窗口。
Loop
Close #1
下面這個函數可以將文本文件的數據一次讀入到一個字符串（但是若包含中文時會出錯，因為一個中文字占2個字節）。
Public Function ReadText(FileName As String)
Dim fnum%, isopen As Boolean
On Error GoTo erro
fnum = FreeFile()
Open FileName For Input As #fnum
isopen = True
ReadText = Input(LOF(fnum), fnum)
erro:
If isopen Then Close #fnum
If err Then Debug.Print err.Number, err.Description
End Function
12、Print # 語句
語法：Print #filenumber, [outputlist]
outputlist 參數的設置如下：
[{Spc(n) | Tab[(n)]}] [expression] [charpos]
Spc(n) 用來在輸出數據中插入空白字符，而 n 指的是要插入的空白字符數。
Tab(n) 用來將插入點定位在某一絕對列號上，這里，n 是列號。使用無參數的 Tab 將插入點定位在下一個打印區的起始位置。
expression 要打印的數值表達式或字符串表達式。
charpos 指定下一個字符的插入點。使用分號將插入點定位在上一個顯示字符之后。用 Tab(n) 將插入點定位在某一絕對的列號上，用無參數的 Tab 將插入點定位在下一個打印區的起始處。如果省略 charpos，則在下一行打印下一個字符。
功能：將格式化顯示的數據寫入順序文件中。
說明:通常用 Line Input # 或 Input 讀出 Print # 在文件中寫入的數據。
示例：
Open “F:\test.txt” For Output As #1 ’ 打開輸出文件。
Print #1, “This is a test” ’ 將文本數據寫入文件。
Print #1, ’ 將空白行寫入文件。
Print #1, “Zone 1”; Tab; “Zone 2” ’ 數據寫入兩個區（print zones）。
Print #1, “Hello”; " "; “World” ’ 以空格隔開兩個字符串。
Print #1, Spc(5); "5 leading spaces " ’ 在字符串之前寫入五個空格。
Print #1, Tab(10); “Hello” ’ 將數據寫在第十列。
’ 賦值 Boolean、Date、Null 及 Error 等。
Dim MyBool, MyDate, MyNull, MyError
MyBool = False: MyDate = #2/12/1969#: MyNull = Null
MyError = CVErr(32767)
’ True、False、Null 及 Error 會根據系統的地區設置自動轉換格式。
’ 日期將以標準的短式日期的格式顯示。
Print #1, MyBool; " is a Boolean value"
Print #1, MyDate; " is a date"
Print #1, MyNull; " is a null value"
Print #1, MyError; " is an error value"
Close #1
以上代碼寫入的內容如下：
This is a test
Zone 1 Zone 2
Hello World
5 leading spaces
Hello
False is a Boolean value
1969-2-12 is a date
Null is a null value
Error 32767 is an error value
13、Width # 語句
語法：Width #filenumber, width
width 必要。范圍在 0–255 之間的數值表達式，在新的一行開始之前，指出在該行上可出現多少字符。如果 width 等于 0，則行的長度不受限制。width 的缺省值為 0。
功能：將一個輸出行的寬度指定給用 Open 語句打開的文件。
示例：
Dim I
Open “f:\TESTFILE.txt” For Output As #1
Width #1, 5 ’ 設置輸出行寬為 5。
For I = 0 To 9 ’ 循環 10 次。
Print #1, Chr(48 + I); ’ 每行輸出五個字符。
Next I
Close #1
以上代碼寫入的內容如下：
01234
56789
（四）處理二進制文件
打開二進制文件可以使用Open語句的Random和Binary方式打開。二進制文件讀寫使用Get和Put語句。
1、Put 語句
語法：Put [#]filenumber, [recnumber], varname
recnumber 可選。Variant (Long)。記錄號（Random 方式的文件）或字節數（Binary 方式的文件），指明在此處開始寫入。
說明：通常用 Get 將 Put 寫入的文件數據讀出來。
示例：
Dim num As Long, text As String
num = 12345
text = “a string”
Open “f:\data.bin” For Binary As #1 '打開或創建一個二進制文件
Put #1, , num '寫入4個字節
Put #1, , text '寫入8個字節（字符串長為8）
Close #1
2、Get 語句
語法：Get [#]filenumber, [recnumber], varname
recnumber 可選。Variant (Long)。記錄號（Random 方式的文件）或字節數（Binary 方式的文件），以表示在此處開始讀出數據。
功能：將一個已打開的磁盤文件讀入一個變量之中。
說明：通常用 Put 將 Get 讀出的數據寫入一個文件。
示例：讀取以上代碼寫入的內容
Dim num As Long, text As String
Open “f:\data.bin” For Binary As #1
Get #1, , num
text = Space$(8) '準備8個字節的字符串
Get #1, , text '讀入
Debug.Print num, text
Close #1
在立即窗口可以看到如下內容：
12345 a string
3、Seek 語句
語法：Seek [#]filenumber, position
其中position 為介于 1～ 2,147,483,647（相當于 2^31 – 1）之間的數字，指出下一個讀寫操作將要發生的位置。
功能：在 Open 語句打開的文件中，設置下一個讀/寫操作的位置。
說明：可以用Seek語句指定Get語句的讀取位置，但在 Get 及 Put 語句中指定的記錄號將覆蓋由 Seek 語句指定的文件位置。
示例：
Dim MaxSize, NextChar, MyChar
Open “TESTFILE” For Input As #1
MaxSize = LOF(1) ’ 取得文件的總字符數。
’ 用循環讀入所有記錄，但是從最后的記錄開始往前讀。
For NextChar = MaxSize To 1 Step -1
Seek #1, NextChar ’ 設置讀寫位置。
MyChar = Input(1, #1) ’ 讀入一字符。
Next NextChar
Close #1
4、Seek 函數
語法：Seek(filenumber)
功能：返回一個 Long，在 Open 語句打開的文件中指定當前的讀/寫位置。
說明：在使用Get語句讀取文件時，必須用LOF函數來判斷是否到達文件末尾，而不是用EOF函數。可以使用Seek函數判斷當前位置，然后與LOF的值比較。
示例：
Do While Seek(1) < LOF(1)
'繼續讀取
…
Loop
（五）總結
VBA語句的文件操作涵蓋了文件操作的絕大部分內容，很多函數的使用也很簡單，一般的文件讀寫也非常方便，特別是對文本文件。但對于復雜的文件讀寫，代碼 的結構和維護性都不好。因此在VB6之后，微軟引入了FileSystemObject對象模型，提供了面向對象的類庫，來操作驅動器、文件夾和文件。但 對于二進制文件的操作，目前還只能用VBA語句。
Excel文件本身就是二進制文件，它使用的文件格式叫做BIFF(Binary Interchange File Format)，即二進制可交換文件格式（但2007開始使用OOXML格式）。關于其內部的結構，本人也在研究中。以二進制結構打開Excel文件，不 但可以讀取其表格中的數據，還可以讀取其所有的信息（包括密碼）。注意，以Open語句打開文件，并不是我們通常的雙擊一個文件打開顯示到屏幕上，而是將 其存放在磁盤上的數據讀入到緩沖區，不是可視化的打開。這種打開是不需要密碼的，即使你的Excel文件設置了打開密碼，還是照打開不誤，這也正是 Excel文件不安全的根源所在。我以前發過一篇關于破解的文章，里面破解VBA工程密碼的方法就是用二進制替換。由于論壇不讓討論破解的話題，這里就不 再詳細分析代碼了，感興趣的請自行研究。當然，Excel的其他密碼也是可類似破解的，前提是你必須十分了解Excel的內部結構，知道密碼放在哪里，才 能替換。知道的解密的方法，自然可以針對性的改進加密的方法。好了，這里就不再羅嗦了，如果對Excel的內部結構感興趣，可以先看這篇文章，看懂再說。
http://club.excelhome.net/dispbbs.asp?BoardID=2&ID=227502&replyID=&skin=0
Excel-VBA操作文件四大方法之三
三、利用FileSystemObject對象來處理文件
FileSystemObject對象模型，是微軟提供的專門用來訪問計算機文件系統的，具有大量的屬性、方法和事件。其使 用面向對象的“object.method”語法來處理文件夾和文件，使用起來十分方便（需Office 2000以后版本）。FileSystemObject并不是VBA的一部分，它是以一個COM組件的形式提供的。因此，要使用先要創建 FileSystemObject對象。
FileSystemObject對象模型包含了下面的對象和集合：
·FileSystemObject 主對象，包含用來創建、刪除和獲得有關信息，以及用來操作驅動器、文件夾和文件的方法和屬性。
·Drive 對象，包含用來獲得信息的方法和屬性，這些信息是關于連接在系統上的驅動器的，如有多少可用空間等。驅動器不一定是硬盤，也可以是CD－ROM、U盤甚至是通過網絡在邏輯上連接的硬盤（如公司里部門共享的服務器網絡硬盤）。
·Drives 集合，提供驅動器的列表，這些驅動器以實物或在邏輯上與系統相連接。Drives集合包括所有驅動器，與類型無關。
·File 對象，包含用來創建、刪除或移動文件的方法和屬性。
·Files 集合，提供包含在文件夾內的所有文件的列表。
·Folder 對象，包含用來創建、刪除或移動文件夾的方法和屬性。
·Folders 集合，提供包含在文件夾內的所有文件夾的列表。
·TextStream 對象，用來讀寫文本文件。
（一）準備工作
要使用FileSystemObject對象，先要創建它。創建FileSystemObject對象要使用CreatObject函數。CreateObject 函數用來創建并返回一個對 ActiveX 對象的引用。
語法：CreateObject(class,[servername])
class 是要創建的應用程序名稱和類。
servername 要在其上創建對象的網絡服務器名稱。（如果要在遠程計算機上創建對象才用）
class 參數使用 appname.objecttype 這種語法，包括以下部分：
appname 必需的；提供該對象的應用程序名。
objecttype 必需的；待創建對象的類型或類。
因此，我們用下面的代碼創建FileSystemObject對象:
Dim fso As Object
Set fso = CreateObject(“Scripting.FileSystemObject”)
Scripting是類型庫的名稱，FileSystemObject就是要創建的對象的名字。
同樣我們可以創建Dictionary 對象如下：
Dim d
Set d = CreateObject(“Scripting.Dictionary”)
（二）FileSystemObject對象的方法
FileSystemObject對象模型中有些功能是重復的，如可用FileSystemObject對象的CpoyFile方法，也可用File對象的Copy方法來復制文件。下面先介紹FileSystemObject對象的方法。
1、GetDrive 方法
語法：object.GetDrive drivespec
drivespec參數可以是一個驅動器字符（c）、一個驅動器字符加一個冒號（c:）、一個驅動器字符加冒號和路徑分隔符（c:\）或任何網絡共享的說明（\computer2\share1）。
作用：返回一個與指定路徑中的驅動器相對應的 Drive 對象。
示例：
Dim d
Set d = fso.GetDrive(“D:”) '變量d就代表了驅動器D對象
如果 drivespec 不符合任何一種可以接受的形式或者不存在，則發生一個錯誤。
注意：為簡潔，示例中都假定fso是已經創建的FileSystemObject對象
2、GetDriveName 方法
語法：object.GetDriveName(path)
作用：返回一個包含指定路徑的驅動器名字的字符串。
示例：
Debug.Print fso.GetDriveName(“c:\test.txt”) '立即窗口顯示"c:"
3、GetExtensionName 方法
語法：object.GetExtensionName(path)
作用：返回一個包含路徑中最后部件擴展名的字符串。
示例：
Debug.Print fso.GetExtensionName(“c:\test.txt”) '立即窗口顯示"txt"
4、GetBaseName 方法
語法：object.GetBaseName(path)
作用：返回一個包含路徑中最后部件的基本名字（去掉任何文件擴展名）的字符串。
示例：
Debug.Print fso.GetBaseName(“c:\abc\test.txt”) '立即窗口顯示"test"
5、GetAbsolutePathName 方法
語法：object.GetAbsolutePathName(pathspec)
作用：從提供的路徑說明中返回一個完整、明確的路徑。
示例：
如果pathspec為空字符串""，則返回當前路徑。假設當前路徑為C:\Documents and Settings\yc\My Documents
Debug.Print fs.GetAbsolutePathName("") '顯示C:\Documents and Settings\yc\My Documents
Debug.Print fs.GetAbsolutePathName(“c:…”) '顯示C:\Documents and Settings\yc，即上層目錄
Debug.Print fs.GetAbsolutePathName(“abc”) '顯示C:\Documents and Settings\yc\My Documents\abc
Debug.Print fs.GetAbsolutePathName(“c:\test.txt”) '顯示C:\test.txt
6、GetFile 方法
語法：object.GetFile(filespec)
作用：返回一個和指定路徑中文件相對應的 File 對象。
示例：
Dim f
Set f = fso.GetFile(“c:\test.txt”) '變量f就代表了文件test.txt對象
注意：如果指定的文件不存在，則發生一個錯誤。
7、GetFileName 方法
語法：object.GetFileName(pathspec)
作用：返回指定路徑中的最后部件，該路徑不是驅動器說明的一部分。
示例：
Debug.Print fso.GetFileName(“c:\abc\test.txt”) '立即窗口顯示"test.txt"
8、GetFolder 方法
語法：object.GetFolder(folderspec)
作用：返回一個和指定路徑中文件夾相對應的 Folder 對象。
示例：
Dim fd
Set fd = fso.GetFolder(“c:\windows”) '變量f就代表了文件夾windows對象
注意：如果指定的文件夾不存在，則發生一個錯誤。
9、GetSpecialFolder 方法
語法：object.GetSpecialFolder(folderspec)
作用：返回指定的特殊文件夾。
說明：
folderspec 參數可為任何的下列值：
WindowsFolder 0 Windows 文件夾，包含由 Windows 操作系統安裝的文件。
SystemFolder 1 系統文件夾，包含庫、字體、設備驅動程序。
TemporaryFolder 2 Temp 文件夾，用于存儲臨時文件。它的路徑在 TMP 環境變量中。
10、GetParentFolderName 方法
語法：object.GetParentFolderName(path)
作用：返回一個包含指定路徑最后部件父文件夾名字的字符串。
示例：
Debug.Print fso.GetParentFolderName(“c:\tmp\test.txt”) '顯示"c:\tmp"
11、GetTempName 方法
語法：object.GetTempName
作用：返回一個隨機產生的臨時文件或文件夾的名字，該名字在執行需要臨時文件或文件夾的操作時有用。
說明：GetTempName 方法不產生一個文件，它僅提供一個臨時文件名字，該名字可被 CreateTextFile 用于創建一個文件。
示例：
Debug.Print fso.GetTempName '顯示"radB0208.tmp",每次都會變。
12、BuildPath 方法
語法：object.BuildPath(path, name)
作用：追加一個名字到一個已經存在的路徑。
示例：
Debug.Print fso.BuildPath(“c:\tmp”, “abc”) '顯示"c:\tmp\abc"
13、CreateFolder 方法
語法：object.CreateFolder(foldername)
作用：創建一個文件夾。
注意：如果指定的文件夾已經存在，則發生一個錯誤。
示例：
fso.CreateFolder(“c:\myfolder”) '在C盤創建一個myfolder文件夾
14、CopyFolder 方法
語法：object.CopyFolder source, destination[, overwrite]
source 必需的。指明一個或多個被復制文件夾的字符串文件夾說明，可以包括通配符。
destination 必需的。指明 source 中被復制文件夾和子文件夾的接受端的字符串，不允許有通配符。
overwrite 可選的。Boolean 值，它表示已存在的文件夾是否被覆蓋。如果為 True，文件被覆蓋。如果為 False，文件不被覆蓋。缺省值為 True。
作用：復制一個文件夾到另一個地方。
說明：
① 通配符僅可用于 source 參數的最后一個路徑部件。
例如：fso.CopyFolder “c:\mydocuments\letters*”, “c:\tempfolder” 這是可以的。
但不能這樣：fso.CopyFolder “c:\mydocuments**”, “c:\tempfolder”
② 如果 source 包含通配符或 destination 以路徑分隔符（\）為結尾，則認為 destination 是一個已存在的文件夾，在其中復制相匹配的文件夾和子文件夾。否則認為 destination 是一個要創建的文件夾的名字。
例如：fso.copyfolder “c:\tmp”, “f:\abc”
如果F盤沒有abc文件夾，將發生錯誤。如果存在，可看到abc文件夾里有tmp文件夾。
假如寫成這樣：fso.copyfolder “c:\tmp”, “f:\abc”
此時若abc不存在，將創建abc文件夾，且將tmp文件夾里的內容復制到abc文件夾里，而不是tmp文件夾，只有abc是一個已經存在的文件夾時，才復制整個tmp文件夾到abc文件夾里。
③如果 destination 是一個已存在的文件，則發生一個錯誤。
④如果 destination 是一個目錄，它將嘗試復制文件夾和它所有的內容。如果一個包含在 source 的文件已在 destination 中存在，當 overwrite 為 False 時發生一個錯誤，否則它將嘗試覆蓋這個文件。
⑤如果 destination 是一個只讀目錄，當嘗試去復制一個已存在的只讀文件到此目錄并且 overwrite為 False 時，則發生一個錯誤。
⑥如果 source 不存在或使用的通配符不能和任何文件夾匹配，也發生一個錯誤。
⑦CopyFolder 方法停止在它遇到的第一個錯誤上，之前所做的操作是不會消失的，所以要注意。
15、MoveFolder 方法
語法：object.MoveFolder source, destination
參數與CopyFolder的前兩個一樣。
作用：將一個或多個文件夾從一個地方移動到另一個地方。
說明：
①只有在操作系統支持的情況下，這個方法才允許文件夾在卷之間移動。Windows是不允許的，將C盤的文件夾移到D盤是不行的。
②如果 source 包含通配符或 destination 以路徑分隔符 （\） 為結尾，則認為 destination 指定了一個已存在的文件夾，在此文件夾中移動相匹配的文件。否則，認為 destination 是一個要創建的目標文件夾名字。這點與CopyFolder是一樣的。
③如果 destination 是一個已存在的文件，則發生一個錯誤。
④如果 destination 是一個目錄，則發生一個錯誤。
例如：
fso.movefolder “c:\tmp”, “c:” '發生錯誤。
⑤如果 source 不存在或使用的通配符不能和任何文件夾匹配，也發生一個錯誤。
⑥MoveFolder 方法停止在它遇到的第一個錯誤上。不要嘗試回卷在錯誤發生前所做的任何改變。
16、DeleteFolder 方法
語法：object.DeleteFolder folderspec[, force]
folderspec 必需的。要刪除的文件夾的名字。 Folderspec 可以在最后的路徑部件中包含通配符。
force 可選的。Boolean 值，如果要刪除具有只讀屬性設置的文件夾，其值為 True，如果值為 False （缺省），則不能刪除具有只讀屬性設置的文件夾。
作用：刪除一個指定的文件夾和它的內容。
說明：如果沒有發現相匹配的文件夾，則發生一個錯誤。DeleteFolder 方法停止在它遇到的第一個錯誤上，不要嘗試回卷或撤消錯誤發生前所做的任何改變。
示例：
fso.DeleteFolder(“c:\tmp”)
17、FolderExists 方法
語法：object.FolderExists(folderspec)
作用：如果指定的文件夾存在返回 True，不存在返回 False。
18、DriveExists 方法
語法：object.DriveExists(drivespec)
作用：如果指定的驅動器存在，返回 True，如果不存在返回 False。
19、FileExists 方法
語法：object.FileExists(filespec)
作用：如果指定的文件存在，返回 True，若不存在，則返回 False。
20、CreateTextFile 方法
語法：object.CreateTextFile(filename[, overwrite[, unicode]])
overwrite 可選的。Boolean 值，表示一個已存在文件是否可被覆蓋。如果可被覆蓋其值為 True，其值為 False 時不能覆蓋。如果它被省略，則已存在文件不能覆蓋。
unicode 可選的。Boolean 值，表示文件是作為一個 Unicode 文件創建的還是作為一個ASCII 文件創建的。如果作為一個 Unicode 文件創建，其值為 True，作為一個 ASCII 文件創建，其值為 False。如果省略的話，則認為是一個 ASCII 文件。
作用：創建一個指定的文件名并且返回一個用于該文件讀寫的 TextStream 對象。
示例：
Dim f
Set f = fso.CreateTextFile(“c:\testfile.txt”, True)
21、OpenTextFile 方法
語法：object.OpenTextFile(filename[, iomode[, create[, format]]])
作用：打開一個指定的文件并返回一個 TextStream 對象，該對象可用于對文件進行讀、寫、追加操作。
說明：
·iomode 參數可為下面設置值中的任何值：
ForReading 1 打開一個只讀文件，不能對此文件進行寫操作。
ForWriting 2 打開一個用于寫操作的文件。如果和此文件同名的文件已存在，則覆蓋以前內容。
ForAppending 8 打開一個文件并寫到文件的尾部。
注意：在VBA幫助里是沒有ForWriting的，其實是有的，VBA幫助也是有錯誤的。另外，這些常數在使用前要先聲明，或者直接用數值。
·create 可選的，它表示如果指定的 filename 不存在是否可以創建一個新文件。如果創建新文件，其值為 True。若不創建文件其值為 False。缺省值為 False。
·Format 參數可為下面設置值中的任何值：
TristateUseDefault –2 使用系統缺省打開文件。
TristateTrue –1 以 Unicode 格式打開文件。
TristateFalse 0 以 ASCII 格式打開文件。
示例：
Dim f
Set f = fso.OpenTextFile(“c:\testfile.txt”, 2, True)
或者：
Const ForWriting = 2
Set f = fso.OpenTextFile(“c:\testfile.txt”, ForWriting, True)
這兩者功能是一樣的，一個聲明了常量，一個直接用數值。都是在C盤創建文件testfile.txt（如不存在），或以寫的方式打開（如存在）。
22、CopyFile 方法
語法：object.CopyFile source, destination[, overwrite]
作用：把一個或多個文件從一個地方復制到另一個地方。
說明：需要注意的地方與CopyFolder是完全類似的。
示例：
fso.copyfile “c:\testfile.txt”, “f:\abc” '若abc不存在則出錯。
fso.copyfile “c:\testfile.txt”, “f:\abc” '若abc不存在則復制testfile.txt到F盤文件名變為abc，若abc存在，出錯，因為是一個目錄。
23、MoveFile 方法
語法：object.MoveFile source, destination
作用：將一個或多個文件從一個地方移動到另一個地方。
說明：需要注意的地方與MoveFolder是完全類似的。
24、DeleteFile 方法
語法：object.DeleteFile filespec[, force]
作用：刪除一個指定的文件。
說明：force 可選的。如果要刪除具有只讀屬性設置的文件，其值為 True。如果其值為 False （缺省），則不能刪除具有只讀屬性設置的文件。
（三）處理驅動器
可以利用Drive對象來獲取有關各種驅動器的信息，Drive對象的屬性有：
TotalSize 屬性 驅動器的總容量，以字節為單位。
AvailableSpace 屬性 驅動器的可用空間容量，以字節為單位。
FreeSpace 屬性 驅動器的剩余空間容量，和 AvailableSpace 屬性是相同的。
對于支持限額的計算機系統來說，二者之間可能有所不同。
DriveLetter 屬性 驅動器字母，即盤符。
DriveType 屬性 驅動器的類型。如"Removable"、“Fixed”、“Network”、“CD-ROM”、“RAM Disk”
SerialNumber 屬性 驅動器的序列號。
FileSystem 屬性 驅動器所使用的文件系統類型。如FAT、FAT32、NTFS、以及 CDFS。
IsReady 屬性 驅動器是否可用。
ShareName 屬性 驅動器的網絡共享名。
VolumeName 屬性 驅動器的卷標名。
Path 屬性 驅動器的路徑。C 驅動器的路徑是 C:，而不是 C:\。
RootFolder 屬性 定驅動器的根文件夾。C 驅動器的根文件夾是 C:\。
這些屬性的使用都十分簡單，直接用“對象.屬性”就可以了。在使用前要先用GetDrive獲得一個Drive對象，注意不能創建一個驅動器對象。下面舉個例子：
Sub ShowFreeSpace(drvPath)
Dim fs, d, s
Set fs = CreateObject(“Scripting.FileSystemObject”)
Set d = fs.Getdrive(fs.GetDriveName(drvPath))
s = "Drive " & UCase(drvPath) & “-”
s = s & d.VolumeName & vbCrLf
s = s & “Free Space: " & FormatNumber(d.FreeSpace / 1024, 0)
s = s & " Kbytes”
MsgBox s
End Sub
利用Call ShowFreeSpace(“c:”)，即可獲得C盤的卷標名和可用空間。
（四）處理文件夾
1、獲取文件夾的信息
可以利用Folder對象來獲取有關文件夾的信息，Folder對象的屬性有：
Attributes 屬性 文件夾的屬性。可為下列值中的任意一個或任意的邏輯組合：
Normal 0 一般文件。未設置屬性。
ReadOnly 1 只讀文件。屬性為讀/寫。
Hidden 2 隱藏文件。屬性為讀/寫。
System 4 系統文件。屬性為讀/寫。
Volume 8 磁盤驅動器卷標。屬性為只讀。
Directory 16 文件夾或目錄。屬性為只讀。
Archive 32 自上次備份后已經改變的文件。屬性為讀/寫。
Alias 64 鏈接或快捷方式。屬性為只讀。
Compressed 128 壓縮文件。屬性為只讀。
Name 屬性 文件夾名字。
ShortName 屬性 較早的 8.3 命名約定的程序所使用的短名字。
Type 屬性 文件夾類型。
Files 屬性 所有 File 對象組成的 Files 集合，這些 File 對象包含在指定的文件夾中
──包括設置了隱藏和系統文件屬性的那些文件。
Drive 屬性 文件夾所在的驅動器符號。
IsRootFolder 屬性 文件夾是否是根文件夾。
ParentFolder 屬性 文件夾的父文件夾對象。
SubFolders 屬性 文件夾的子文件夾集合。
Path 屬性 文件夾的路徑。
ShortPath 屬性 較早的 8.3 文件命名約定的程序所使用的短路徑。
Size 屬性 文件夾的大小，以字節為單位。
DateCreated 屬性 文件夾的創建日期和時間。
DateLastModified 屬性 最后一次修改文件夾的日期和時間。
DateLastAccessed 屬性 最后一次訪問文件夾的日期和時間。
屬性的使用和Drive對象是一樣的，可以用GetFolder獲取一個Folder對象，也可以用FileSystemObject對象的CreateFolder 方法創建一個Folder對象。
2、Folder對象的方法
⑴Copy 方法
語法：object.Copy destination[, overwrite]
作用：把一個指定的文件夾從一個地方復制到另一個地方。
說明：Copy 方法的作用與FileSystemObject對象的CopyFolder 方法是一樣的，不同在于后者可一次復制多個文件夾。
⑵Move 方法
語法：object.Move destination
作用：將一個指定的文件夾從一個地方移動到另一個地方。
說明：Move 方法的作用與FileSystemObject.MoveFolder 是一樣的。不同在于后者可一次移動多個文件夾。
⑶Delete 方法
語法：object.Delete force
作用：刪除一個指定的文件夾。
說明：Delete 方法的作用與FileSystemObject.DeleteFolder 是一樣的。
⑷CreateTextFile 方法
語法：object.CreateTextFile(filename[, overwrite[, unicode]])
作用：與FileSystemObject對象的CreateTextFile 方法是一樣的。
示例：
Set fd = fs.getfolder(“c:\tmp”)
Set f = fd.CreateTextFile(“testfile.txt”, True)
可在C盤tmp文件夾下創建testfile.txt文件。
（五）處理文件
1、獲取文件的信息
可以利用File對象來獲取有關文件的信息，File對象的屬性和Folder的屬性是完全一樣的，只是少了Files 屬性、IsRootFolder 屬性、SubFolders 屬性這3個屬性。這里就不列了。
2、File對象的方法
⑴Copy 方法
⑵Move 方法
⑶Delete 方法
以上三種方法與Folder的是完全類似的，語法也一樣，同樣也可用FileSystemObject對象相應的方法代替。
⑷OpenAsTextStream 方法
語法：object.OpenAsTextStream([iomode, [format]])
作用：打開一個指定的文件并返回一個 TextStream 對象，該對象可用來對文件進行讀、寫、追加操作。
說明：此方法與FileSystemObject對象的 OpenTextFile 方法相同的功能。參數也是一致的。
（六）處理文本文件
1、打開或創建文本文件
打開現有的文本文件，可以使用FileSystemObject對象的 OpenTextFile 方法或File對象的OpenAsTextStream 方法。
創建文件可以使用FileSystemObject對象的 CreatTextFile 方法或在OpenTextFile 方法中將iomode參數設為ForWriting＝2，create參數設為True。
例如：
Set f = fso.OpenTextFile(“c:\test1.xls”, 2, True) '如果不存在test1.xls將自動創建。
2、讀取文件
打開文件后，將返回一個TextStream 對象，我們可以利用TextStream 對象的屬性及方法來對文件進行讀寫操作。
先看TextStream 對象的幾個屬性。
·AtEndOfLine 屬性 文件指針是否正好在行尾標記的前面
·AtEndOfStream 屬性 文件指針是否在 TextStream 文件末尾
·Column 屬性 TextStream 文件中當前字符位置的列號
·Line 屬性 TextStream 文件中的當前行號
利用TextStream 對象讀取文件有三種方法。
·Read 方法
語法：object.Read(characters)
功能：從一個 TextStream 文件中讀取指定數量的字符并返回得到的字符串。
示例：
Sub du()
Dim fso, a, retstring
Const ForReading = 1
Set fso = CreateObject(“Scripting.FileSystemObject”)
Set a = fso.OpenTextFile(“c:\testfile.txt”, ForReading, False)
Do While a.AtEndOfLine <> True '是否到行末
retstring = retstring & a.Read(1) '讀取一個字符
Loop
a.Close
Debug.Print retstring '可看到讀取了第一行的字符
End Sub
·ReadLine 方法
語法：object.ReadLine
功能：從一個 TextStream 文件讀取一整行（到換行符但不包括換行符）并返回得到的字符串。
示例：
Sub du_line()
Dim fso, a, retstring
Const ForReading = 1
Set fso = CreateObject(“Scripting.FileSystemObject”)
Set a = fso.OpenTextFile(“c:\testfile.txt”, ForReading, False)
Do While a.AtEndOfStream <> True '是否在 TextStream 文件末尾
retstring = a.ReadLine '讀取一行
Debug.Print retstring '顯示在立即窗口
Loop
a.Close
End Sub
·ReadAll 方法
語法：object.ReadAll
功能：讀取整個的 TextStream 文件并返回得到的字符串。
說明：對于大的文件，使用ReadAll方法浪費內存資源。應使用其它的技術去輸入一個文件，比如按行讀取文件。
示例：
Sub du_all()
Dim fso, a, retstring
Const ForReading = 1
Set fso = CreateObject(“Scripting.FileSystemObject”)
Set a = fso.OpenTextFile(“c:\testfile.txt”, ForReading, False)
retstring = a.Readall '全部讀取
Debug.Print retstring
a.Close
End Sub
還有兩個輔助讀取的方法：
·Skip 方法
語法：object.Skip(characters)
功能：當讀一個 TextStream 文件時跳過指定數量的字符。
示例：
Sub duskip()
Dim fso, a, retstring
Const ForReading = 1
Set fso = CreateObject(“Scripting.FileSystemObject”)
Set a = fso.OpenTextFile(“c:\testfile.txt”, ForReading, False)
Do While a.AtEndOfLine <> True '是否到行末
retstring = retstring & a.Read(1) '讀取一個字符
a.Skip (1) '跳過一個字符
Loop
a.Close
Debug.Print retstring '可看到讀取了第一行的奇數位的字符
End Sub
·SkipLine 方法
語法：object.SkipLine
功能：當讀一個 TextStream 文件時跳過下一行。
3、寫入數據到文件
寫入數據到文件也有三種方法。
·Write 方法
語法：object.Write(string)
功能：寫一個指定的字符串到一個 TextStream 文件。
示例：
Sub xie()
Const ForWriting = 2, ForAppending = 8
Dim fs, f
Set fs = CreateObject(“Scripting.FileSystemObject”)
Set f = fs.OpenTextFile(“c:\testfile.txt”, ForAppending,TristateFalse)
f.Write “Hello world!” '寫入字符串
f.Close
End Sub
·WriteLine 方法
語法：object.WriteLine([string])
功能：寫入一個指定的字符串和換行符到一個 TextStream 文件中。
示例：
f.WriteLine(“Hello world!”) '寫入字符串，加一個換行符。
·WriteBlankLines 方法
語法：object.WriteBlankLines(lines)
功能：寫入指定數量的換行符到一個 TextStream 文件中。
示例：
f.WriteBlankLines(3) '相當于按3次回車。
4、關閉文件
利用TextStream 對象的Close方法，上面的示例中已經有了，很簡單。
（七）總結
從上面的介紹，我們看到使用FileSystemObject對象處理文件、文件夾比使用VBA語句的方法具有更容易存在的特點。這是因為 FileSystemObject對象使用了面向對象的語法。另外FileSystemObject對象處理文本文件毫不遜色于VBA語句，非常值得推 薦。唯一的問題是不能處理二進制文件，微軟在有關文檔中稱計劃將來支持二進制文件，不過應該只是計劃而已，呵呵。
之四
四、利用API函數來處理文件
通過前面三種方法的介紹，你是否已經覺得足夠了？是的，前面的方法完全可以應付幾乎所有的文件操作。但是為了普及一下API，展示一下API的魅力，最后向大家介紹一下如何利用API函數來處理文件。另一方面也是本人對API情有獨鐘，為她做一下廣告，呵呵。
大家對API的強大也是有所耳聞了，在文件操作方面，API自然毫不遜色。
說明：為了文章簡潔，我們先給出API函數的名稱及功能，其完整的聲明及常數就不再一一細訴，只在示例中給出其完整用法。
（一）處理驅動器及目錄
下面是windows中提供的對于目錄進行操作的API函數及其功能:
CreateDirectory,CreateDirectoryEx 創建一個新目錄
GetCurrentDirectory 在一個緩沖區中裝載當前目錄
GetDiskFreeSpace,GetDiskFreeSpaceEx 獲取與一個磁盤的組織有關的信息，以及了解剩余空間的容量
GetDriveType 判斷一個磁盤驅動器的類型
GetFullPathName 獲取指定文件的完整路徑名
GetLogicalDrives 判斷系統中存在哪些邏輯驅動器字母
GetLogicalDriveStrings 獲取一個字串，其中包含了當前所有邏輯驅動器的根驅動器路徑
GetSystemDirectory 這個函數能取得Windows系統目錄（System目錄）的完整路徑名。在這個目錄中，包含了所有必要的系統文件。根據微軟的標準，其他定制控件和一 些共享組件也可放到這個目錄。通常應避免在這個目錄里創建文件。在網絡環境中，往往需要管理員權限才可對這個目錄進行寫操作
GetTempPath 獲取為臨時文件指定的路徑
GetVolumeInformation 獲取與一個磁盤卷有關的信息
GetWindowsDirectory 這個函數能獲取Windows目錄的完整路徑名。在這個目錄里，保存了大多數windows應用程序文件及初始化文件
RemoveDirectory 刪除指定目錄
SetCurrentDirectory 設置當前目錄
SetVolumeLabel 設置一個磁盤的卷標（Label）
下面通過幾個例子來詳細的了解一下其中主要的幾個函數及其用法：
1、GetLogicalDrives
作用：判斷系統中存在哪些邏輯驅動器字母
聲明：Declare Function GetLogicalDrives Lib “kernel32” Alias “GetLogicalDrives” () As Long
說明：此函數的返回值類型為Long，這個結構中的二進制位標志著存在哪些驅動器。其中，位0設為1表示驅動器A:存在于系統中；位1設為1表示存在B:驅動器；以次類推
示例：
Public Sub Get_LogicalDrives()
Dim LDs As Long, Cnt As Long, sDrives As String
LDs = GetLogicalDrives
sDrives = “Available drives:”
For Cnt = 0 To 25
If (LDs And 2 ^ Cnt) <> 0 Then
sDrives = sDrives + " " + Chr$(65 + Cnt)
End If
Next Cnt
MsgBox sDrives
End Sub
上面的示例中，我們通過二進制運算，將返回值轉換成字符。如果你的機上有C,D,E,F,G,H這幾個驅動器，那么LDs的值就是252，轉成二進制為11111100，從右往左，依次代表A,B,C,D,…，為0的說明沒有此驅動器字母。大家可以自己試一試。
2、GetDriveType
作用：判斷一個磁盤驅動器的類型
聲明：Declare Function GetDriveType Lib “kernel32” Alias “GetDriveTypeA” (ByVal nDrive As String) As Long
說明：此函數的返回值類型為Long，如驅動器不能識別，則返回零。如指定的目錄不存在，則返回1。如執行成功，則用下述任何一個常數指 定驅動器類型：DRIVE_REMOVABLE（表示磁盤可以從驅動器上移走，通常是軟驅）， DRIVE_FIXED（磁盤不能從驅動器上移走，通常為本地硬盤）， DRIVE_REMOTE（驅動器是遠程網絡驅動器）， DRIVE_CDROM（驅動器是CD-ROM驅動器） 或 DRIVE_RAMDISK（驅動器是RAM驅動器）
參數為String類型，包含了驅動器根目錄路徑的一個字串
此函數的功能與FSO的Drive對象的DriveType屬性是一樣的。
示例：
'定義常數變量
Private Const DRIVE_CDROM = 5 '表示光盤驅動器
Private Const DRIVE_FIXED = 3 '表示硬盤驅動器
Private Const DRIVE_RAMDISK = 6 '表示RAM驅動器
Private Const DRIVE_REMOTE = 4 '表示網絡驅動器
Private Const DRIVE_REMOVABLE = 2 '表示軟盤驅動器
Private Sub Get_DriveType()
Dim temp As Long
temp = GetDriveType(“d:”) '取的d:盤驅動器類型
Select Case temp
Case DRIVE_CDROM
MsgBox “DRIVE_CDROM: 光盤驅動器”
Case DRIVE_FIXED
MsgBox “DRIVE_FIXED: 硬盤驅動器”
Case DRIVE_RAMDISK
MsgBox “DRIVE_RAMDISK: RAM驅動器”
Case DRIVE_REMOTE
MsgBox “DRIVE_REMOTE: 網絡驅動器”
Case DRIVE_REMOVABLE
MsgBox “DRIVE_REMOVABLE: 軟盤驅動器”
End Select
End Sub
3、GetDiskFreeSpaceEx
作用：獲取與一個磁盤的組織以及剩余空間容量有關的信息
聲明：Declare Function GetDiskFreeSpaceEx Lib “kernel32” Alias “GetDiskFreeSpaceExA” (ByVal lpRootPathName As String, lpFreeBytesAvailableToCaller As LARGE_INTEGER, lpTotalNumberOfBytes As LARGE_INTEGER, lpTotalNumberOfFreeBytes As LARGE_INTEGER) As Long
說明：此函數的返回值類型為Long，非零表示成功，零表示失敗。會設置GetLastError.
在采用FAT16格式的windows95系統中，如一個驅動器（分區）的容量超過了2GB，則不應使用這個函數。此時，這個函數能識別的最大分區容量只有2GB
參數說明：
lpRootPathName String，不包括卷名的磁盤根路徑名
lpFreeBytesAvailableToCaller LARGE_INTEGER，指定一個變量，用于容納調用者可用的字節數量
lpTotalNumberOfBytes LARGE_INTEGER，指定一個變量，用于容納磁盤上的總字節數
lpTotalNumberOfFreeBytes LARGE_INTEGER，指定一個變量，用于容納磁盤上可用的字節數
LARGE_INTEGER結構用來代表一個64位帶符號的整數值，它的定義如下：
Type LARGE_INTEGER ’ 8 Bytes
lowpart As Long
highpart As Long
End Type
其中lowpart為 Long，指定低32位,highpart 為 Long，指定高32位。
示例：雖然此函數能識別的最大分區容量只有2GB，但通過調整，對大于2G的仍然能得出正確容量。以下的調整公式是本人通過逆向推算出來的，至于其中的原理也不是很清楚，大家可一測試一下。
Private Sub Get_DiskFreeSpaceEx()
Dim temp As Long, Dms$
Dim tempa, tempb, tempc
Dim RootPathName As String
Dim FreeBytesAvailabletoCaller As LARGE_INTEGER
Dim TotalNumberOfBytes As LARGE_INTEGER
Dim TotalNumberOfFreeBytes As LARGE_INTEGER
RootPathName = “d:”
'取得磁盤空間
temp = GetDiskFreeSpaceEx(RootPathName, FreeBytesAvailabletoCaller, TotalNumberOfBytes, TotalNumberOfFreeBytes)
Dms = Dms + “磁盤容量:” + vbCrLf
tempa = TotalNumberOfBytes.highpart * 2 ^ 32 + IIf(TotalNumberOfBytes.lowpart > 0, TotalNumberOfBytes.lowpart, TotalNumberOfBytes.lowpart + 2 ^ 32) '計算容量
Dms = Dms + CStr(tempa) + “字節” + vbCrLf
tempa = Format(tempa / 1024 / 1024 / 1024, “0.00”)
Dms = Dms + tempa + “G” + vbCrLf
'取得磁盤可用空間
Dms = Dms + “磁盤可用空間:” + vbCrLf
tempb = TotalNumberOfFreeBytes.highpart * 2 ^ 32 + IIf(TotalNumberOfFreeBytes.lowpart > 0, TotalNumberOfFreeBytes.lowpart, TotalNumberOfFreeBytes.lowpart + 2 ^ 32) '計算
Dms = Dms + CStr(tempb) + “字節” + vbCrLf
tempb = Format(tempb / 1024 / 1024 / 1024, “0.00”)
Dms = Dms + tempb + “G” + vbCrLf
'取得磁盤已用空間
Dms = Dms + “磁盤已用空間:” + vbCrLf
tempc = tempa - tempb
Dms = Dms + CStr(tempc) + “G” + vbCrLf
MsgBox Dms
End Sub
4、CreateDirectory, CreateDirectoryEx
作用：創建一個新目錄
聲明：
Declare Function CreateDirectory& Lib “kernel32” Alias “CreateDirectoryA” (ByVal lpNewDirectory As String, lpSecurityAttributes As SECURITY_ATTRIBUTES)
Declare Function CreateDirectoryEx& Lib “kernel32” Alias “CreateDirectoryExA” (ByVal lpTemplateDirectory As String, ByVal lpNewDirectory As String, lpSecurityAttributes As SECURITY_ATTRIBUTES)
說明：此函數的返回值類型為Long，非零表示成功，零表示失敗。會設置GetLastError
參數說明：
lpTemplateDirectory String，指定一個模板目錄的名字，從中復制默認屬性（比如目錄中文件的默認壓縮方式）。如設為vbNullString，則表示不使用模板
lpNewDirectory String，新目錄的名字
lpSecurityAttributes SECURITY_ATTRIBUTES，這個結構定義了目錄的安全特性——如果操作系統支持的話
示例：
Private Sub Create_Directory()
Dim Security As SECURITY_ATTRIBUTES
'創建目錄
Ret& = CreateDirectory(“C:\Directory”, Security)
'若返回0，則失敗。
If Ret& = 0 Then MsgBox “Error : 創建失敗!”, vbCritical + vbOKOnly
End Sub
5、RemoveDirectory
作用：移除一個目錄
聲明：Declare Function RemoveDirectory Lib “kernel32” Alias “RemoveDirectoryA” (ByVal lpPathName As String) As Long
說明：此函數的返回值類型為Long，非零表示成功，零表示失敗。會設置GetLastError.
在調用這個函數前，目錄必須為空
參數說明：
lpPathName 為String類型，要刪除的那個目錄的名字
示例：
Private Sub Remove_Directory()
Dim Security As SECURITY_ATTRIBUTES
CreateDirectoryEx “C:\Windows”, “C:\Temp”, Security
'移除目錄
RemoveDirectory “C:\Temp”
End Sub
6、SetCurrentDirectory
作用：設置當前目錄，與VBA語句ChDir類似。
聲明：Declare Function SetCurrentDirectory Lib “kernel32” Alias “SetCurrentDirectoryA” (ByVal lpPathName As String) As Long
說明：此函數的返回值類型為Long，非零表示成功，零表示失敗。會設置GetLastError
參數說明：
LpPathName String，新當前目錄的路徑
示例：
SetCurrentDirectory “d:” '設置D:為當前目錄
7、GetSystemDirectory
作用：這個函數能取得Windows系統目錄（System目錄）的完整路徑名。在這個目錄中，包含了所有必要的系統文件。根據微軟的標 準，其他定制控件和一些共享組件也可放到這個目錄。通常應避免在這個目錄里創建文件。在網絡環境中，往往需要管理員權限才可對這個目錄進行寫操作
聲明：Declare Function GetSystemDirectory Lib “kernel32” Alias “GetSystemDirectoryA” (ByVal lpBuffer As String, ByVal nSize As Long) As Long
說明：此函數的返回值類型為Long，裝載到lpBuffer緩沖區的字符數量。如lpBuffer不夠大，不能容下文件名，則返回要求的緩沖區長度
參數說明：
lpBuffer String，用于裝載系統目錄路徑名的一個字串緩沖區。它應事先初始化成nSize+1個字符的長度。通常至少要為這個緩沖區分配MAX_PATH個字符的長度
nSize Long，lpBuffer字串的最大長度
示例：
Private Sub Get_SystemDirectory()
Dim sSave As String, Ret As Long
'創建緩沖區
sSave = Space(255)
'獲取系統目錄
Ret = GetSystemDirectory(sSave, 255)
'移除多余的0
sSave = Left$(sSave, Ret)
'顯示路徑
MsgBox "系統目錄: " + sSave
End Sub
（二）處理文件
下面是windows中提供的對于文件進行操作的API函數及其功能:
CloseHandle 關閉一個內核對象。其中包括文件、文件映射、進程、線程、安全和同步對象等。
CompareFileTime 根據FILETIME結構的信息，對比兩個文件的時間
CopyFile 復制文件。注意：只能復制文件，而不能復制目錄
CreateFile 這是一個全功能的函數，可打開和創建文件、管道、郵槽、通信服務、設備以及控制臺
DeleteFile 刪除指定文件
FindClose 關閉由FindFirstFile函數創建的一個搜索句柄
FindFirstFile 根據文件名查找文件
FindNextFile 根據調用FindFirstFile函數時指定的一個文件名查找下一個文件
FlushFileBuffers 針對指定的文件句柄，刷新內部文件緩沖區
GetBinaryType 判斷文件是否可以執行
GetFileAttributes 判斷指定文件的屬性
GetFileInformationByHandle 該函數能夠獲取上面所有函數所能夠獲取的信息，如大小、屬性等，同時還包括一些其他地方無法獲取的信息，比如：文件卷標、索引和鏈接信息。
GetFileSize 判斷文件長度
GetFileTime 取得指定文件的時間信息，有三個文件時間：創建時間、最后訪問時間、最后寫時間。
GetFileType 在給出文件句柄的前提下，判斷文件類型
GetFileVersionInfo 從支持版本標記的一個模塊里獲取文件版本信息
GetFileVersionInfoSize 針對包含了版本資源的一個文件，判斷容納文件版本信息需要一個多大的緩沖區
GetFullPathName 獲取文件路徑，該函數獲取文件的完整路徑名。注意：只有當該文件在當前目錄下，
結果才正確。如果要得到真正的路徑。應該用GetModuleFileName函數。
GetShortPathName 獲取指定文件的短路徑名
GetTempFileName 這個函數包含了一個臨時文件的名字，它可由應用程序使用
GetTempPath 獲取Windows臨時目錄路徑
lclose 關閉指定的文件，請參考CloseHandle函數，了解進一步的情況
lcreat 創建一個文件。如文件已經存在，就會將其縮短成零長度，并將其打開，以便讀寫
llseek 設置文件中進行讀寫的當前位置。該函數與vba的seek語句類似。
LockFile 在windows中，文件可用共享模式打開——在這種情況下，多個進程可同時訪問該文件。
利用這個函數，要對文件進行讀寫的一個應用程序可將文件的某一部分鎖定起來，使其
不能由其他應用程序訪問。這樣便避免了同時讀寫時發生的沖突
LockFileEx 與LockFile相似，只是它提供了更多的功能
lopen 以二進制模式打開指定的文件
lread 將文件中的數據讀入內存緩沖區
lwrite 將數據從內存緩沖區寫入一個文件
MoveFile, MoveFileEx 移動文件。如dwFlags設為零，則MoveFile完全等價于MoveFileEx
OpenFile 這個函數能執行大量不同的文件操作。和這個函數相比，請優先考慮CreateFile函數
（它能打開命名管道和控制Unicode文件名，同時不受128個字符的路徑名稱的限制）
ReadFile 從文件中讀出數據。與lread函數相比，這個函數要明顯靈活的多。該函數能夠操作
通信設備、管道、套接字以及郵槽
ReadFileEx 與ReadFile相似，只是它只能用于異步讀操作，并包含了一個完整的回調
SearchPath 查找指定文件
SetEndOfFile 針對一個打開的文件，將當前文件位置設為文件末尾
SetFileAttributes 設置文件屬性
SetFilePointer 在一個文件中設置當前的讀寫位置
SetFileTime 設置文件的創建、訪問及上次修改時間
UnlockFile 解除對一個文件的鎖定
UnlockFileEx 解除對一個文件的鎖定
WriteFile 將數據寫入一個文件。該函數比lwrite函數要靈活的多。也可將這個函數應用于對
通信設備、管道、套接字以及郵槽的處理
WriteFileEx 與WriteFile類似，只是它只能用于異步寫操作，并包括了一個完整的回調
文件的壓縮和解壓縮
LZOpenFile 打開壓縮文件以讀取
LZSeek 查找壓縮文件中的一個位置
LZRead 讀一個壓縮文件
LZClose 關閉一個壓縮文件
LZCopy 復制壓縮文件并在處理過程中展開
GetExpandedName 從壓縮文件中返回文件名稱。
下面通過幾個例子來詳細的了解一下其中主要的幾個函數及其用法：
1、CreateFile
作用：這是一個全功能的例程，可打開和創建文件、管道、郵槽、通信服務、設備以及控制臺
聲明：
Declare Function CreateFile Lib “kernel32” Alias “CreateFileA” (ByVal lpFileName As String, ByVal dwDesiredAccess As Long, ByVal dwShareMode As Long, lpSecurityAttributes As SECURITY_ATTRIBUTES, ByVal dwCreationDisposition As Long, ByVal dwFlagsAndAttributes As Long, ByVal hTemplateFile As Long) As Long
說明：
此函數的返回值類型為Long，如執行成功，則返回文件句柄。INVALID_HANDLE_VALUE表示出錯，會設置 GetLastError。即使函數成功，但若文件存在，且指定了CREATE_ALWAYS 或 OPEN_ALWAYS，GetLastError也會設為ERROR_ALREADY_EXISTS
打開一個通信端口時（如COM1），無論如何都要設置成 OPEN_EXISTING。
這個函數代替了lOpen 和 lCreate函數，應該是我們的首選
參數說明：
·lpFileName String，要打開的文件的名字
·dwDesiredAccess Long，如果為 GENERIC_READ 表示允許對設備進行讀訪問；如果為 GENERIC_WRITE 表示允許對設備進行寫訪問（可組合使用）；如果為零，表示只允許獲取與一個設備有關的信息
·dwShareMode Long，零表示不共享； FILE_SHARE_READ 和/或 FILE_SHARE_WRITE 表示允許對文件進行共享訪問
·lpSecurityAttributes SECURITY_ATTRIBUTES，指向一個SECURITY_ATTRIBUTES結構的指針，定義了文件的安全特性（如果操作系統支持的話）
·dwCreationDisposition
Long，下述常數之一：
CREATE_NEW 創建文件；如文件存在則會出錯
CREATE_ALWAYS 創建文件，會改寫前一個文件
OPEN_EXISTING 文件必須已經存在。由設備提出要求
OPEN_ALWAYS 如文件不存在則創建它
TRUNCATE_EXISTING 講現有文件縮短為零長度
·dwFlagsAndAttributes
Long，一個或多個下述常數
FILE_ATTRIBUTE_ARCHIVE 標記歸檔屬性
FILE_ATTRIBUTE_COMPRESSED 將文件標記為已壓縮，或者標記為文件在目錄中的默認壓縮方式
FILE_ATTRIBUTE_NORMAL 默認屬性
FILE_ATTRIBUTE_HIDDEN 隱藏文件或目錄
FILE_ATTRIBUTE_READONLY 文件為只讀
FILE_ATTRIBUTE_SYSTEM 文件為系統文件
FILE_FLAG_WRITE_THROUGH 操作系統不得推遲對文件的寫操作
FILE_FLAG_OVERLAPPED 允許對文件進行重疊操作
FILE_FLAG_NO_BUFFERING 禁止對文件進行緩沖處理。文件只能寫入磁盤卷的扇區塊
FILE_FLAG_RANDOM_ACCESS 針對隨機訪問對文件緩沖進行優化
FILE_FLAG_SEQUENTIAL_SCAN 針對連續訪問對文件緩沖進行優化
FILE_FLAG_DELETE_ON_CLOSE 關閉了上一次打開的句柄后，將文件刪除。特別適合臨時文件
也可在Windows NT下組合使用下述常數標記：
SECURITY_ANONYMOUS， SECURITY_IDENTIFICATION， SECURITY_IMPERSONATION， SECURITY_DELEGATION， SECURITY_CONTEXT_TRACKING， SECURITY_EFFECTIVE_ONLY
·hTemplateFile Long，如果不為零，則指定一個文件句柄。新文件將從這個文件中復制擴展屬性
示例如下:
lngHandle = CreateFile(“c:\text.txt”, GENERIC_WRITE, FILE_SHARE_READ Or FILE_SHARE_WRITE, ByVal 0&, OPEN_ALWAYS, 0, 0)
'上面代碼以寫方法打開文件，如文件不存在則創建它。
2、lcreat
作用：創建一個文件。如文件已經存在，就會將其縮短成零長度，并將其打開，以便讀寫
聲明：Declare Function lcreat Lib “kernel32” Alias “_lcreat” (ByVal lpPathName As String, ByVal iAttribute As Long) As Long
說明：此函數的返回值類型為Long，如執行成功，返回打開文件的句柄。如果出錯，則返回HFILE_ERROR
該函數會打開已由其他應用程序打開的文件，所以使用它時要小心。win32的CreateFile函數已取代了這個函數。這個函數與vb的open語句作用相同
參數說明：
lpPathName String，欲創建的文件的名字
iAttribute Long，下述值之一：
0——文件能夠讀寫
1——創建只讀文件
2——創建隱藏文件
3——創建系統文件
示例：
下面的語句打開c：\test.txt文件
lcreat “c:\test.txt”,0
3、lopen
作用：以二進制模式打開指定的文件
聲明：Declare Function lopen Lib “kernel32” Alias “_lopen” (ByVal lpPathName As String, ByVal iReadWrite As Long) As Long
說明：此函數的返回值類型為Long，如執行成功，返回打開文件的句柄。HFILE_ERROR表示出錯。會設置GetLastError
參數說明：
lpPathName String，欲打開文件的名字
iReadWrite Long，訪問模式和共享模式常數的一個組合，如下所示：
1、訪問模式
READ 打開文件，讀取其中的內容
READ_WRITE 打開文件，對其進行讀寫
WRITE 打開文件，在其中寫入內容
2、共享模式（參考OpenFile函數的標志常數表）
OF_SHARE_COMPAT， OF_SHARE_DENY_NONE， OF_SHARE_DENY_READ， OF_SHARE_DENY_WRITE， OF_SHARE_EXCLUSIVE
示例：
lopen “c:\test.txt”,READ
4、GetFileTime
作用：取得指定文件的時間信息
聲明：Declare Function GetFileTime Lib “kernel32” Alias “GetFileTime” (ByVal hFile As Long, lpCreationTime As FILETIME, lpLastAccessTime As FILETIME, lpLastWriteTime As FILETIME) As Long
說明：Long，非零表示成功，零表示失敗。會設置GetLastError
如果不需要特定的信息，那么lpCreationTime，lpLastAccessTime，lpLastWriteTime都可以設置為零（用ByVal As Long）。這個函數返回的文件時間采用UTC格式
參數說明：
hFile Long，文件的句柄
lpCreationTime FILETIME，用于裝載文件的創建時間
lpLastAccessTime FILETIME，用于裝載文件上一次訪問的時間（FAT文件系統不支持這一特性）
lpLastWriteTime FILETIME，用于裝載文件上一次修改的時間
示例：
Dim file As Long
Dim CreationTime As FileTime
Dim lastaccesstime As FileTime
Dim lastaccesstime As FileTime
'定義結構
Private Type FileTime
dwLowDateTime As Long
dwHighDateTime As Long
End Type
str1 = “c:\text.txt”
file = lopen(str1, READ_WRITE) '打開文件
temp = GetFileTime(file, CreationTime, lastaccesstime, lastwritetime)’得到文件相關信息
以上代碼獲取的時間信息是Long型的，還需要時間轉換函數進行轉換，完整的示例見附件。
5、CopyFile
作用：復制文件。與vb的filecopy命令相似
聲明：Declare Function CopyFile Lib “kernel32” Alias “CopyFileA” (ByVal lpExistingFileName As String, ByVal lpNewFileName As String, ByVal bFailIfExists As Long) As Long
說明：Long，非零表示成功，零表示失敗。會設置GetLastError
參數說明：
lpExistingFileName String，源文件名
lpNewFileName String，目標文件名
bFailIfExists Long，如果設為TRUE（非零），那么一旦目標文件已經存在，則函數調用會失敗。否則目標文件被改寫
示例：
CopyFile “c:\test1.txt”, “c:\test2.txt”, 1
以上代碼將c:\test1.txt 拷貝到c:\test2.txt，完整的示例見附件。
6、MoveFile, MoveFileEx
作用：移動文件。如dwFlags設為零，則MoveFile完全等價于MoveFileEx
聲明：
Declare Function MoveFile Lib “kernel32” Alias “MoveFileA” (ByVal lpExistingFileName As String, ByVal lpNewFileName As String)
Declare Function MoveFileEx Lib “kernel32” Alias “MoveFileExA” (ByVal lpExistingFileName As String, ByVal lpNewFileName As String, ByVal dwFlags As Long)
說明：Long，非零表示成功，零表示失敗。會設置GetLastError
這兩個函數通常不能將文件從一個卷移動到另一個卷。但如設置了MOVEFILE_COPY_ALLOWED標記，MoveFileEx可以做到這一點.
參數說明：
lpExistingFileName String，欲移動的文件名
lpNewFileName String，新文件名
dwFlags Long，一個或多個下述常數
MOVEFILE_REPLACE_EXISTING 如目標文件存在，則將其替換
MOVEFILE_COPY_ALLOWED 如移動到一個不同的卷，則復制文件并刪除原來的文件
MOVEFILE_DELAY_UNTIL_REBOOT 移動操作在系統下次重新啟動時正式進行。這樣便可在Windows NT中改換系統文件
示例：
Private Const MOVEFILE_COPY_ALLOWED = &H2
Private Const MOVEFILE_DELAY_UNTIL_REBOOT = &H4
Private Const MOVEFILE_REPLACE_EXISTING = &H1
MoveFile “c:\test.txt”, “d:\test1.txt” '移動文件
MoveFileEx “d:\test1.txt”, “c:\test.txt”, MOVEFILE_COPY_ALLOWED '再一次移動
以上代碼實現了文件的移動，兩次移動後，文件不變
7、DeleteFile
作用：刪除指定文件
聲明：Declare Function DeleteFile Lib “kernel32” Alias “DeleteFileA” (ByVal lpFileName As String) As Long
說明：Long，非零表示成功，零表示失敗。會設置GetLastError
與vba的kill語句相似，在windows 95下使用這個函數要小心——即使文件當前正由一個應用程序打開，該函數也會將其刪除.
參數說明：
lpFileName String，欲刪除文件的名字
示例：
DeleteFile “c:\test.txt” '刪除c:\test.txt文件
完整的示例見附件。
8、ReadFile
作用：從文件中讀出數據。與lread函數相比，這個函數要明顯靈活的多。該函數能夠操作通信設備、管道、套接字以及郵槽
聲明：Private Declare Function ReadFile Lib “kernel32” Alias “ReadFile” (ByVal hFile As Long, lpBuffer As Any, ByVal nNumberOfBytesToRead As Long, lpNumberOfBytesRead As Long, lpOverlapped As OVERLAPPED) As Long
說明：Long，非零表示成功，零表示失敗。會設置GetLastError。如啟動的是一次異步讀操作，則函數會返回零值，并將 ERROR_IO_PENDING設置成GetLastError的結果。如結果不是零值，但讀入的字節數小于nNumberOfBytesToRead 參數指定的值，表明早已抵達了文件的結尾
參數：
hFile ---- Long，文件的句柄
lpBuffer — Any，用于保存讀入數據的一個緩沖區
nNumberOfBytesToRead - Long，要讀入的字符數
lpNumberOfBytesRead - Long，從文件中實際讀入的字符數
lpOverlapped — OVERLAPPED，如文件打開時指定了FILE_FLAG_OVERLAPPED，那么必須用這個參數引用一個特殊的結構。那個結構定義了一次異步讀 取操作。否則，應將這個參數設為NULL（將函數聲明成ByVal As Long，并傳遞零值）
示例：完整的示例見附件。
9、WriteFile
作用：將數據寫入一個文件。該函數比lwrite函數要靈活的多。也可將這個函數應用于對通信設備、管道、套接字以及郵槽的處理
聲明：Declare Function WriteFile Lib “kernel32” Alias “WriteFile” (ByVal hFile As Long, lpBuffer As Any, ByVal nNumberOfBytesToWrite As Long, lpNumberOfBytesWritten As Long, lpOverlapped As OVERLAPPED) As Long
說明：Long，TRUE（非零）表示成功，否則返回零。會設置GetLastError
參數：
hFile — Long，一個文件的句柄
lpBuffer — Any，要寫入的一個數據緩沖區
nNumberOfBytesToWrite - Long，要寫入數據的字節數量。如寫入零字節，表示什么都不寫入，但會更新文件的“上一次修改時間”。針對位于遠程系統的命名管道，限制在65535個字節以內
lpNumberOfBytesWritten - Long，實際寫入文件的字節數量
lpOverlapped — OVERLAPPED，倘若在指定FILE_FLAG_OVERLAPPED的前提下打開文件，這個參數就必須引用一個特殊的結構。那個結構定義了一次異 步寫操作。否則，該參數應置為空（將聲明變為ByVal As Long，并傳遞零值）
示例：完整的示例見附件。
10、SHFileOperation
作用：此函數的功能很強大，能對文件或文件夾進行復制、移動、重命名、刪除的全部操作。
聲明：Declare Function SHFileOperation Lib “shell32.dll” Alias “SHFileOperationA” (lpFileOp As SHFILEOPSTRUCT) As Long
說明：Long，TRUE（非零）表示成功，否則返回零。
參數：
lpFileOp －－SHFILEOPSTRUCT類型，指定文件的操作。
Type SHFILEOPSTRUCT
hwnd As Long
wFunc As Long '對文件的操作指令
pFrom As String '源文件或路徑
pTo As String '目的文件或路徑
fFlags As Integer '操作標志
fAnyOperationsAborted As Long
hNameMappings As Long
lpszProgressTitle As String
End Type
示例：見附件。
（三）總結
通過以上的介紹，我們可以看到API在文件操作方面功能十分強大，能夠完成一些前面方法所不能完成的任務。FileSystemObject對象模 型的內部可能就是用API寫的，即便不是我們也可以用API寫出一個FSO類來。API是一個巨大的寶庫，當你為實現某個功能而愁眉不展的時候，查查 API可能就能找到滿意的答案。
寫的這么多，希望對大家有所幫助，至少操作文件是沒有什么問題了。
附件：API函數示例，代碼有注釋，應該都看的懂，可以按F8逐行運行，查看結果。
總結
以上是生活随笔為你收集整理的Excel-VBA操作文件四大方法之一（转）的全部內容，希望文章能夠幫你解決所遇到的問題。
- 上一篇： Windows Server 2012安
- 下一篇： EASE-Grid投影