批处理菜鸟教程
目錄
一、常用命令簡介
1、echo 命令
2、rem 命令
3、pause 命令
4、call 命令
5、start 命令
6、goto 命令
7、set 命令
二、常用符號簡介
1、回顯屏蔽 @
2、重定向1 >；與>>
3、重定向2 <
4、管道符號 |
5、轉義符 ^
6、邏輯命令符
三、命令釋義
1、文件夾管理
2、文件管理
3、網絡命令
4、系統管理
四、語句結構
1、if語句（選擇結構）
for語句（循環結構）
五、字符串
1、截取字符串
2、替換字符串
3、字符串合并
4、擴充字符串
六、數值計算
七、批處理的相關知識
1、環境變量
2、用戶變量
3、參數
4、返回值
5、ASCII碼
6、ArcGIS中的批處理
八、注意
九、參考鏈接
一、常用命令簡介
1、echo 命令
打開或關閉回顯功能，或顯示消息。
Syntax ：echo [{on|off}] [message]
Sample：@echo off / echo hello world
2、rem 命令
注釋命令
:: 也具有rem的功能
但::和rem還是有區別的，當關閉回顯時，rem和::后的內容都不會顯示。
但是當打開回顯時，rem 后的內容會顯示出來，然而::后的內容仍然不會顯示。
Syntax ：Rem [注釋內容]
Sample：Rem 你好。
3、pause 命令
暫停命令。運行 Pause 命令時，將顯示下面的消息：
Press any key to continue. . .（或：請按任意鍵繼續. . .)
Sample：
@echo off
:begin
copy G:*.* d:\back
echo 請插入另一張光盤...
pause
goto begin
在這個例子中，驅動器 G 中磁盤上的所有文件均復制到d:\back中。顯示的注釋提示您將另一張光盤盤放入驅動器 G 時，pause 命令會使程序掛起，以便您更換光盤，然后按任意鍵繼續處理。
4、call 命令
從一個批處理程序調用另一個批處理程序，并且不終止父批處理程序。
Syntax：call [路徑文件名] [標簽]]
Parametes：[Drive:}[Path] FileName
指定要調用的批處理程序的位置和名稱。
5、start 命令
調用外部程序，所有的DOS命令和命令行程序都可以由start命令來調用。
Sample：start?calc.exe即可打開Windows的計算器。
6、goto 命令
跳轉命令。程序指針跳轉到指定的標簽，從標簽后的第一條命令開始繼續執行批處理程序。
Syntax：goto label （label是參數，指定所要轉向的批處理程序中的行。）
Sample：
:label
start
goto label
運行以上這段命令，就會打開很多個窗口（用來整人相當不錯）。這段命令的意思是，先用start命令打開窗口，再用goto label命令轉到label標簽，即第一行后面的命令。注意標簽名字前面要加上英文的冒號。
7、set 命令
顯示、設置或刪除變量。
顯示變量：set 或 set s 前者顯示批處理當前已定義的所有變量及其值，后者顯示所有以s開頭的變量及值。
設置和調用變量：例如set aa=abcd，就是把aa定義為abcd。如果要調用這個變量，就把aa兩邊加上個百分號。
例如：
set aa=abcd
echo %aa%
pause
運行這段命令就會顯示“abcd”。
刪除變量：set aa= 此句命令即可刪除變量aa。若變量aa已被定義，則刪除變量aa；若aa尚未定義，則此句命令無實質意義。
需要說明的是，批處理中的變量是不區分類型的，不需要像C語言中的變量那樣還要區分int、float、char等。比如執行set aa=345后，變量aa的值既可以被視為數字345，也可以被視為字符串345。
set命令具有擴展功能，如用作交互輸入、字符串處理、數值計算等，屬于高級命令范疇。
二、常用符號簡介
1、回顯屏蔽 @
表示不顯示@后面的命令。
Sample：通過運行批處理文件對比pause和@pause命令即可明了@的效果。
2、重定向1 >；與>>
將輸出信息重定向到指定的設備或文件。系統默認輸出到顯示器。
Sample：echo aaaaa>a.txt?
將aaaaa輸出到文件a.txt中。若文件a.txt本來已經存在，該命令將首先擦除a.txt中的所有信息，然后寫入信息aaaaa；若a.txt本來就不存在，該命令即可新建一個a.txt文件，并寫入信息aaaaa。
Sample：echo aaaaa>>a.txt
和echo aaaaa>a.txt的區別在于：若a.txt已經存在時，>>會追加在a.txt文本中；若a.txt不存在時，兩者沒有區別。
需要注意的是，因為數字的特殊性，在echo輸出數字時，請在后面加上空格，例如：echo 9313 >a.txt，否則有可能造成輸出不完整。
3、重定向2 <
將輸入信息來源重定向為指定的設備或文件。系統默認從顯示器讀取輸入信息。
重定向使用舉例：
=========================================
@echo off
echo abcdefg——這是文件a.txt中的信息>a.txt
echo 請任意輸入字符，以回車結束：
set /p ifo=
cls
echo 【 從屏幕獲得的輸入信息 】
echo %ifo%
set /p ifo=<a.txt
echo 【 從文件a.txt獲得的輸入信息 】
echo %ifo%
pause>nul
=========================================
讀者觀察命令與輸出即可體會到重定向的功能和效果。
4、管道符號 |
Syntax：command_1|command_2
將command_1的輸出重定向為command_2的輸入。
Sample：
=========================================
@echo off
echo aaaa>a.txt
del /p a.txt
pause
=========================================
@echo off
echo aaaa>a.txt
echo y|del /p a.txt
pause
=========================================
對比以上兩個批處理執行結果，讀者即可明白管道符的用法和效果。
5、轉義符 ^
將特殊符號轉化為一般符號，即剝離特殊符號的特殊地位。特殊符號指：| & > <
比如，如果我們想輸出符號“>；”，直接用命令 echo > 是不行的，必須修改為 echo ^>；。其余幾個特殊符號類似需要有同樣的處理。
Sample：
=========================================
@echo off
echo aaaa>a.txt
echo 第一句echo執行完畢
echo aaaa^>a.txt
echo 第二句echo執行完畢
pause
=========================================
比較上面的兩句echo，第一句echo將信息aaaa輸出到了文件a.txt，而第二句echo則在直接屏幕上顯示出aaaa>a.txt
6、邏輯命令符
邏輯命令符包括：&；、&&；、||
&-它的作用是用來連接n個DOS命令，并把這些命令按順序執行，而不管是否有命令執行失敗；
&&-當&&；前面的命令成功執行時，執行&&；后面的命令，否則不執行；
||-當||前面的命令失敗時，執行||后面的命令，否則不執行。
=========================================
@echo off
echo ^|^|
reg add HKCU /v try /f||echo **失敗**
reg add HKCU1 /v try /f||echo **成功**
echo ^&^&
reg delete HKCU /v try /f&&echo **成功**
reg delete HKCU /v try /f&&echo **失敗**
echo ^&
reg delete HKCU /v try /f&echo **也許成功**
reg delete HKCU /v try /f&echo **也許失敗**
pause
=========================================
執行reg add或reg delete后，系統會給出執行結果；我們通過echo命令也給出了“執行結果”。對比系統和我們自己給出的結果，既可以驗證邏輯命令的判斷機理。
三、命令釋義
1、文件夾管理
cd 顯示當前目錄名或改變當前目錄。
md 創建目錄。
rd 刪除一個目錄。
dir 顯示目錄中的文件和子目錄列表。
tree 以圖形顯示驅動器或路徑的文件夾結構。
path 為可執行文件顯示或設置一個搜索路徑。
copy 復制文件和目錄樹。
2、文件管理
type 顯示文本文件的內容。
copy 將一份或多份文件復制到另一個位置。
del 刪除一個或數個文件。
move 移動文件并重命名文件和目錄。（Windows XP Home Edition中沒有)
ren?重命名文件。
replace 替換文件。
attrib 顯示或更改文件屬性。
find 搜索字符串。
fc 比較兩個文件或兩個文件集并顯示它們之間的不同
3、網絡命令
ping 進行網絡連接測試、名稱解析
ftp文件傳輸
net 網絡命令集及用戶管理
telnet遠程登陸
ipconfig顯示、修改TCP/IP設置
msg 給用戶發送消息
arp 顯示、修改局域網的IP地址-物理地址映射列表
4、系統管理
at 安排在特定日期和時間運行命令和程序
shutdown立即或定時關機或重啟
tskill 結束進程
taskkill結束進程（比tskill高級，但WinXPHome版中無該命令）
tasklist顯示進程列表（Windows XP Home Edition中沒有）
sc 系統服務設置與控制
reg 注冊表控制臺工具
powercfg控制系統上的電源設置
對于以上列出的所有命令，在cmd中輸入命令+/?即可查看該命令的幫助信息。如find /?
四、語句結構
批處理的語句結構主要有選擇結構（if語句）、循環結構（for語句）等。
1、if語句（選擇結構）
if語句實現條件判斷，包括字符串比較、存在判斷、定義判斷等。通過條件判斷，if語句即可以實現選擇功能。
1．字符串比較
if語句僅能夠對兩個字符（串）是否相同、先后順序進行判斷等。其命令格式為：
IF [not] string1 compare-op string2 command1 [else command2]
其中，比較操作符compare-op有以下幾類：
== - 等于
EQU - 等于
NEQ - 不等于
LSS - 小于
LEQ - 小于或等于
GTR - 大于
GEQ - 大于或等于
選擇開關/i則不區分字符串大小寫；選擇not項，則對判斷結果進行邏輯非。
字符串比較示例：
=
@echo off
set str1=abcd1233
set str2=ABCD1234
if %str1%==%str2% (echo 字符串相同！) else (echo 字符串不相同！)
if /i %str1% LSS %str2% (echo str1^<str2) else (echo str1^>=str2)
echo.
set /p choice=是否顯示當前時間？（y/n)
if /i not %choice% EQU n echo 當前時間是：%date% %time%
pause>nul
對于最后一個if判斷，當我們輸入n或N時的效果是一樣的，都不會顯示時間。如果我們取消開關/i，則輸入N時，依舊會顯示時間。
另外請注意一下幾個細節：1-echo str1^<str2和echo str1^>=str2；2-echo.。
2．存在判斷
存在判斷的功能是判斷文件或文件夾是否存在。其命令格式為：
IF [NOT] EXIST filename command1 [else command2]
@echo off
if exist %0 echo 文件%0是存在的！
if not exist %~df0 (
echo 文件夾%~df0不存在！
） else echo 文件夾%~df0存在！
pause>nul
這里注意幾個地方：
1-存在判斷既可以判斷文件也可以判斷文件夾；
2-%0即代表該批處理的全稱（包括驅動器盤符、路徑、文件名和擴展類型）；
3-%~df0是對%0的修正，只保留了其驅動器盤符和路徑，詳情請參考for /?，屬高級批處理范疇；
4-注意if語句的多行書寫，多行書寫要求command1的左括號必須和if在同一行、else必須和command1的右括號同行、command2的左括號必須與else同行、command1和command2都可以有任意多行，即command可以是命令集。
3．定義判斷
定義判斷的功能是判斷變量是否存在，即是否已被定義。其命令格式為：
IF [not] DEFINED variable command1 [else command2]
存在判斷舉例：
@echo off
set var=111
if defined var (echo var=%var%) else echo var尚未定義！
set var=% %
if defined var (echo var=%var%) else echo var尚未定義！
pause>nul
對比可知，"set var="可以取消變量，收回變量所占據的內存空間。
4．結果判斷
masm %1.asm
if errorlevel 1 pause & edit %1.asm
link %1.obj
先對源代碼進行匯編，如果失敗則暫停顯示錯誤信息，并在按任意鍵后自動進入編輯界面；否則用link程序連接生成的obj文件，這種用法是先判斷前一個命令執行后的返回碼（也叫錯誤碼，DOS程序在運行完后都有返回碼），如果和定義的錯誤碼符合（這里定義的錯誤碼為1），則執行相應的操作（這里相應的操作為pause & edit %1.asm部分）。
另外，和其他兩種用法一樣，這種用法也可以表示否定。用否定的形式仍表達上面三句的意思，代碼變為：
masm %1.asm
if not errorlevel 1 link %1.obj
pause & edit %1.asm
for語句（循環結構）
1．無開關
無開關的for語句能夠對設定的范圍內進行循環，是最基本的for循環語句。其命令格式為：
Syntax：for?%%v?in?(set)? do?command
%%v是批處理程序里面的書寫格式，注意v只能是單字符。在DOS中書寫為%v，即只有一個百分號（%）；
set就是需要我們設定的循環范圍，類似于C語言里面的循環變量；
do后面的command就是循環所執行的命令，即循環體。
無開關for語句舉例：
===============================================
@echo off
for %%i in (a,"b c",d) do echo %%i
pause>nul
===============================================
2．開關/L
含開關/L的for語句，可以根據set里面的設置進行循環，從而實現對循環次數的直接控制。其命令格式為：
for /L %%v?in?(start,step,end) do?command
其中，start為開始計數的初始值，step為每次遞增的值，end為結束值。當end小于start時，step需要設置為負數。
含開關/L的for語句舉例（創建5個文件夾）：
===============================================
@echo off
for /l %%i in (1,2,10) do md %%i
pause
===============================================
上例將新建5個文件夾，文件夾名稱依次為1．3．5．7．9。可以發現，%%i的結束值并非end的值10，而是不大于end的一個數。
3．開關/f
含開關/f的for語句可以解析字符串和文本。其命令格式為：
for? /f?["options"] %%v in (set) do command
其中，set為（"string"、'command'、file-set）中的一個；options是（eol=c、skip=n、delims=xxx、tokens=x,y,m-n、usebackq）中的一個或多個的組合。各選項的意義參見for /f。一般情況下，使用較多的是skip、tokens、delims三個選項。
? ? ? 1、字符串解析：
===============================================
@echo off
echo **No Options:
for /f %%a in ("1,2,10") do echo a=%%a
echo **Options tokens ^& delims:
for /f "tokens=1-3 delims=," %%a in ("1,2,10") do echo a=%%a b=%%b c=%%c
pause
===============================================
? ? ? 2、文本解析
@echo off
echo 本文件夾里面的文件有：
for /f "skip=5 tokens=3* delims= " %%a in ('dir') do (
if not "%%a"=="<DIR>" if not "%%b"=="字節" if not "%%b"=="可用字節" echo %%b
)
pause
===============================================
@echo off
echo 本文件夾里面的文件有：
dir>c:\file.txt
for /f "skip=5 tokens=3* delims= " %%a in (c:\file.txt) do (
if not "%%a"=="<DIR>" if not "%%b"=="字節" if not "%%b"=="可用字節" echo %%b
)
del c:\file.txt
pause
===============================================
對于后面的兩個例子，其中options里面的delims= 是可以刪除的，因為只要添加了/f開關系統就將delims的值默認為空格。
符號字符串中的最后一個字符星號，
那么額外的變量將在最后一個符號解析之后
分配并接受行的保留文本。本例中也可以改為4，不過文件名中有空格的文件，只能顯示空格以前部分
同時我們也看到了，for語句的do后面的command也是可以分行的，只需要保證command的左括號和do在同一行就可以了。
4．開關/D或/R
含開關/D或/R的for語句是與目錄或文件有關的命令，一般情況下很少使用。含開關/R的命令有時候被用于通過遍歷文件夾來查找某一個文件或文件夾，故而列舉此例。
含開關/R的for語句舉例（文件夾遍歷）：
===============================================
@echo off
setlocal enabledelayedexpansion
for /r?d: %%i in??(.)? do??(
set dd=%%i
set "dd=!dd:~0,-1!"
echo !dd!
）
pause
exit
===============================================
上例即可以羅列出D盤下的所有文件夾，其速度要比命令"tree d:"慢多了，不過其返回結果的實用性則遠遠超過了tree命令。
一般情況下我們不推薦通過遍歷文件夾來查找文件，特別是在查找某些程序（比如QQ.exe）的位置時。推薦通過reg命令查找注冊表來查找QQ的路徑，以保證查找效率。
%dd%：變量dd的值不變
!dd!：動態刷新變量dd的值
!dd!需要開啟延時擴展變量擴展
開啟延遲環境變量擴展：setlocal enabledelayedexpansion。
停用延遲環境變量擴展：SetLocal DisableDelayedExpansion
for語句是批處理里面功能最強大、使用最普遍卻又最難掌握的一套命令，這也是批處理菜鳥和批處理高手最明顯的一個分水嶺，一旦掌握了這套命令，那么你就離批處理達人不遠了！
五、字符串
1、截取字符串
截取字符串可以說是字符串處理功能中最常用的一個子功能了，能夠實現截取字符串中的特定位置的一個或多個字符。
舉例說明其基本功能：
=========================================
@echo off
set ifo=abcdefghijklmnopqrstuvwxyz0 12 3456789
echo 原字符串（第二行為各字符的序號）：
echo %ifo%
echo 1234567890123 45678901234567890123456
echo 截取前5個字符：
echo %ifo:~0,5%
echo 截取最后5個字符：
echo %ifo:~-5%
echo 截取第一個到倒數第6個字符：
echo %ifo:~0,-5%
echo 從第4個字符開始，截取5個字符：
echo %ifo:~3,5%
echo 從倒數第14個字符開始，截取5個字符：
echo %ifo:~-14,5%
pause
=========================================
當然，上面的例子只是將字符串處理的基本功能展示出來了，還看不出字符串處理具體有什么用處。下面這個例子是對時間進行處理。
=========================================
@echo off
echo 當前時間是：%time% 即 %time:~0,2%點%time:~3,2%分%time:~6,2%秒%time:~9,2%厘秒
pause
=========================================
2、替換字符串
替換字符串，即將某一字符串中的特定字符或字符串替換為給定的字符串。舉例說明其功能：
=========================================
@echo off
set aa=偉大的中國！我為你自豪！
echo 替換前：%aa%
echo 替換后：%aa:中國=中華人民共和國%
echo aa = %aa%
set "aa=%aa:中國=中華人民共和國%"
echo aa = %aa%
pause
=========================================
對于上面的例子有一點說明，對比兩個echo aa = %aa%可以發現，如果要修改變量aa的內容的話，就需要將修改結果“%aa：中國=中華人民共和國%”賦值給變量aa。上面的字符串截取也有著同樣的特點。
3、字符串合并
其實，合并字符串就是將兩個字符串放在一起就可以了。舉例說明：
=========================================
@echo off
set aa=偉大的中國！
set bb=我為你自豪！
echo %aa%%bb%
echo aa=%aa%
echo bb=%bb%
set "aa=%aa%%bb%"
echo aa=%aa%
pause
=========================================
同樣，如果要改變變量aa的內容的話，就需要將合并結果“%aa%%bb%”賦值給變量aa。
4、擴充字符串
“擴充”這個詞匯來自于微軟自己的翻譯，意思就是對表示文件路徑的字符串進行特殊的處理，具體功能羅列如下：
=========================================
~I - 刪除任何引號（")，擴充 %I
%~fI - 將 %I 擴充到一個完全合格的路徑名
%~dI - 僅將 %I 擴充到一個驅動器號
%~pI - 僅將 %I 擴充到一個路徑
%~nI - 僅將 %I 擴充到一個文件名
%~xI - 僅將 %I 擴充到一個文件擴展名
%~sI - 擴充的路徑只含有短名
%~aI - 將 %I 擴充到文件的文件屬性
%~tI - 將 %I 擴充到文件的日期/時間
%~zI - 將 %I 擴充到文件的大小
%~$PATH:I - 查找列在路徑環境變量的目錄，并將 %I 擴充
到找到的第一個完全合格的名稱。如果環境變量名
未被定義，或者沒有找到文件，此組合鍵會擴充到
空字符串
可以組合修飾符來得到多重結果：
%~dpI - 僅將 %I 擴充到一個驅動器號和路徑
%~nxI - 僅將 %I 擴充到一個文件名和擴展名
%~fsI - 僅將 %I 擴充到一個帶有短名的完整路徑名
%~dp$PATH:i - 查找列在路徑環境變量的目錄，并將 %I 擴充
到找到的第一個驅動器號和路徑。
%~ftzaI - 將 %I 擴充到類似輸出線路的 DIR
=========================================
以上內容引用于for /?幫助信息。其中的I代表變量I，不過需要說明的是，不是所有的變量都能夠進行擴充的，有兩個條件：1．該字符串代表一個文件路徑；2．變量要用%x來表示，x可取a-z A-Z 0-9共62個字符中的任意一個。舉例說明：
=========================================
@echo off
echo 正在運行的這個批處理：
echo 完全路徑：%0
echo 去掉引號：%~0
echo 所在分區：%~d0
echo 所處路徑：%~p0
echo 文件名：%~n0
echo 擴展名：%~x0
echo文件屬性：%~a0
echo 修改時間：%~t0
echo 文件大小：%~z0
pause
=========================================
其中的%0是批處理里面的參數，代表當前運行的批處理的完全路徑。類似的還有%1-%9，分別代表傳遞來的第1-9個參數。例子如下：
===============================================
@echo off
set aa=C:\Windows\PPP\a.btx
call :deal aaa %aa% "c c" ddd eee
pause>nul
exit
:deal
echo %%0 = %0
echo %%1 = %1
echo %%2 = %2
echo %%3 = %3
echo %%4 = %4
echo %%5 = %5
===============================================
其中，變量aa在之前是不可以擴充的，通過call命令并將aa作為參數傳遞給子函數：deal，將aa變量轉換成了變量%1，即符合%x格式，從而可以進行字符串擴充。
至于%x中x取a-z A-Z的形式，可以復習一下for語句，for語句里面的變量就是用%x來表示的，因而可以直接進行擴充。
六、數值計算
批處理里面的數值計算功能較弱，只能夠進行整型計算，忽略浮點數的小數部分；同時數值計算的范圍也受限于系統位數，對于目前較為常見的32位機來說，數值計算能處理的數值范圍為0x80000000h~0x7FFFFFFFh，即-2147483648~+2147483647。
數值計算需要使用set命令，具體格式為“set /a expression”。其中，expression代表計算表達式，計算表達式跟C語言里面的表達式基本上完全一致。set支持的運算符也跟C語言里面的一樣，只是沒有了増一減一。set支持的運算符及優先級排序如下：
=========================================
（） - 分組
！ ~ - -一元運算符（邏輯非、按位非、取負）
* / % - 算數運算符（乘、除得商、除得余數，即取余）
+ - - 算數運算符（加、減）
<< >> - 邏輯移位（左移一位、右移一位）
& - 按位“與”
^ - 按位“異”
| - 按位“或”
= *= /= %= += -= - 賦值
&= ^= |= <<= >>=
，-表達式分隔符（set可一次處理多個表達式）
=========================================
我們知道，批處理中取變量的值是需要用%或者！的，而在set /a 中，直接用變量名稱即可取得變量的值。另外，set支持八進制（數字前綴0）、十進制（數字無前綴）和十六進制（數字前綴0x），且支持不同進制之間的計算，如set /a a=123+0123+0x123，計算及顯示結果為十進制。
?
七、批處理的相關知識
1、環境變量
批處理的環境變量分為系統變量和用戶變量兩類。
【 1．系統變量】
系統變量是由操作系統事先定義好的，可以適用于任何批處理。系統變量有很多個，包括硬件類、操作系統類、文件路徑類、系統時間類等。
查看所有的系統變的命令：在cmd中輸入set回車。
對幾個比較常用的變量解釋如下：
ComputerName 計算機名，即右鍵我的電腦--屬性--計算機名 選項卡中的“完整的計算機名稱”
ComSpeccmd.exe完整路徑名
HomeDrive：系統分區盤符，一般都是C盤，故而HomeDrive=C:
Path：可執行文件默認搜索路徑。這個東東非常重要！待會兒單獨講解…
ProgramFiles：系統的Program Files的路徑啦，一般都是C:\Program Files，這就是安裝軟件時默認的安裝路徑了
Prompt ：個性化設置cmd提示符的必備武器！不過，我沒怎么用過~
SystemDrive： 包含系統根目錄的分區，其實就是HomeDrive了
SystemRoot ：系統根目錄路徑，一般都是C:\WINDOWS
Temp、Tmp 文件、程序等可使用的臨時目錄，默認是C:\WINDOWS\Temp或Tmp。幾乎所有的程序在運行時都會在這個目錄里面“臨時”寫入文件。一般情況下，程序寫入的臨時文件都應該被該程序刪除，可惜的是，大部分的程序都很健忘，導致這個文件夾占據的空間越來越大，自然也就使我們的系統增肥嘍。所以，我們要把它修改到其他分區，并且時時的清理里面的臨時文件。
UserName 當前用戶名，即所登陸的賬戶名
UserProfile 當前用戶的配置目錄，一般都是C:\Documents and Settings\%UserName%。默認情況下，我們的桌面就是這個目錄下面的“桌面”文件夾；我的文檔就是這個目錄下面的“My Documents”文件夾。所以啦，往桌面上或我的文檔里面放東西就是放到這個文件夾下面了，也就是放到C盤了，重裝系統時要覆蓋C盤內容的，所以桌面上或我的文檔里面的東西當然就會Gone with the Wind了~解決方法有兩個，一是保持良好的習慣，不把重要文件放到這兩個地方；二是，修改默認設置，將這兩個文件夾都移到其他分區。
WinDir操作系統路徑，其實就是SystemRoot了
2、用戶變量
用戶變量是用戶自己定義的變量。用戶變量僅僅在定義該變量的程序中有效。
用戶變量由set命令定義，這是批處理中非常非常重要的一個操作，從而使set命令成為批處理里面使用頻率最高的幾個命令之一。關于set命令的使用，參考set /?，本教程也會在后面對其進行講解。
【 3．變量引用 】
前面的幾節課里面，我們已經看到了如何引用變量，即直接用變量名操作變量，通過"%"或"!"來獲取變量的值。其中，只有在for語句里面重復對同一變量多次賦值時才需要使用"!"，并且在使用"!"調用變量時，要首先“啟用延遲環境變量擴充”，啟動命令為：SetLocal EnableDelayedExpansion。另外需要說明的是，“啟用延遲環境變量擴充”后，所有的"!"都將被視為“取變量值”的特殊符號，即使用"^!"也不能輸出符號"!"。若要輸出"!"，則需要“停用延遲環境變量擴充”，命令為：SetLocal DisableDelayedExpansion
3、參數
跟C語言類似，在調用函數或其他批處理時可能需要傳遞參數。批處理的參數傳遞分為直接和間接兩種傳遞參數的方法。
【 1．直接傳遞 】
直接傳遞參數，即在使用call命令時，不使用任何參數，在子函數或子批處理里面直接對主函數（也稱父批處理）里面的變量進行修改。這跟匯編語言里面的參數傳遞方式類似。
直接傳遞參數舉例：
===============================================
@echo off
setlocal enabledelayedexpansion
set var=aCdehiM,?mnrstW y
echo %var%
call :deal
setlocal disabledelayedexpansion
set var=%var:?=!%
echo %var%
pause>nul
exit
:deal
set tm=!var!
set var=
for %%i in (6,3,11,11,16,15,1,4,11,5,12,13,9,0,12,7,15,14,5,10,2,16,18,8) do (
set var=!var!!tm:~%%i,1!
）
goto :eof
===============================================
可以發現，當我們把變量var作為參數賦予子函數：deal后，子函數對var的值進行了修改；當子函數返回后，主函數里面的var的值就已經是子函數里面var被修改后的值了。
該例子中，使用了本節課前面講到的setlocal enabledelayedexpansion和setlocal disabledelayedexpansion，前者保證了var在for循環里面能夠根據我們的意愿進行處理，后者保證了能夠正確輸出符號"!"。另外例子中還使用了命令set，利用set對字符串進行了處理。還有一個地方使用了語句goto :eof，該語句相當于C語言里面的return或匯編語言里面的RET，即子程序返回命令。需要說明的是，當子函數本身就在批處理文件的末尾的話，我們是可以省略這句話的，比如將此例的goto :eof刪除是不會產生任何影響的。
【 2．間接傳遞 】
間接傳遞參數，即在使用call命令時，在其后面添加參數，形如call {[:label][ChildBatch]} Parameter1 Parameter2 ... ParameterN。這跟C語言里面傳遞參數的格式類似。不同于C語言，批處理中的子函數不需要定義形參，更不需要指定參數的個數。傳遞過來的參數，在子函數或子批處理里面是以%1~%9的形式表示的，即%1~%9分別表示傳遞過來的第1~9個參數。
===============================================
@echo off
call :deal aaa bbb "c c" ddd eee
pause>nul
exit
:deal
echo %%0 = %0
echo %%1 = %1
echo %%2 = %2
echo %%3 = %3
echo %%4 = %4
echo %%5 = %5
===============================================
通過這個例子就可以清晰的看到%n參數表示法的用法。參數列表中包含空格的依舊要用雙引號（")引起來；另外，也可以看到，%0已經變成了子函數的標號了，而不是父批處理的文件名全稱。
【 3．區別 】
這兩種參數傳遞方法本質上是沒有區別的，形式上，直接傳遞直接對原變量進行操作，丟失了原變量的值；間接傳遞則通過%n對原變量進行了簡單的備份，并且通用性更強，即不限定原變量的名稱。另外，使用%n還有一個非常大的好處，就是可以通過%~*i來加強處理變量的能力。關于%~*i，詳細內容參見for /?。
針對二者的差別，可以根據情況決定使用哪種傳遞方式：
--1．作為參數的變量名固定、且在子函數中不需要對其進行備份的情況下，使用直接傳遞法；
--2．若將子函數作為一個通用的程序模塊，以適應于對不同變量的處理，或者作為參數的變量不需要備份時，使用間接傳遞法。
具體使用哪種方法，還需根據實際情況或使用習慣進行選擇。
4、返回值
有些命令在執行之后將會返回一定的錯誤值（errorlevel），可以通過errorlevel的值判斷命令執行的狀況。這點類似于C語言里面的exit(num），num就是錯誤代碼。
獲取返回值errorlevel的方法就是，在執行命令后，立馬調用返回值errorlevel，如echo %errorlevel%或者if %errorlevel%==1等命令。
errorlevel舉例：
===============================================
@echo off
reg add HKCU /v try /f>nul
reg delete HKCU /v try /f
if errorlevel 0 (echo刪除成功！） else (echo 刪除失敗！）
reg delete HKCU /v try /f
if %errorlevel%==0 (echo 刪除成功！） else (echo 刪除失敗！）
pause>nul
===============================================
上面例子中，由于第一成功的刪除了注冊表，導致第二次因為找不到注冊表而宣告失敗。同時我們也看到了errorlevel的使用方法，即if errorlevel 0和if %errorlevel%==0是一樣的。也許你注意到了，里面還有個笑臉呢~O（∩_∩）O哈哈~這就是ASCII碼啦，后面跟你講啊…
一般情況下，程序或命令成功執行時，返回的errorlevel是0，錯誤時返回1或更高的值。當然，有些命令是沒有返回值的，這點需要注意。
嗯，有沒有想起前面有個類似的東西啊？對了，那就是||和&&；了，這兩個符號就是根據errorlevel的值來進行邏輯判斷的。
5、ASCII碼
前面的例子中，我們已經使用過一次ASCII碼了，也就是那個笑臉。ASCII碼是圖形化的符號，可以用來點綴我們的批處理的。
在cmd窗口中我們可以通過任意一個字符的ASCII碼來輸入該字符，比如Ctrl+G、Ctrl+N等，字母a-z對應ASCII碼的97-122。對于ASCII碼大于26的字符，可以通過這個方法來輸入：按住Alt鍵不松，通過小鍵盤輸入ASCII碼的十進制值，松開Alt鍵即可。
6、ArcGIS中的批處理
可別告訴我您不知道什么是批處理，當面對一大堆需要重復操作的數據時，往往讓我們感到頭大，這時候我們會想到批處理[1]??，那ArcGIS給大家提供了哪些批處理的方法呢，讓我們拭目以待。
假設我們需要給道路建立緩沖區，設計到的工具為Buffer。
第一種情況，一個圖層中不同要素建立不同大小的緩沖區
不同類型的道路，我們需要建立不同大小的緩沖區，比如，一級道路建立10米的緩沖區，二級道路建立15米的緩沖區，三級道建立20米的緩沖區。
步驟：
1、 首先應該保證你的道路數據里面有一個屬性字段是用來存儲Buffer寬度信息的。
2、 應用Buffer工具，在對應的參數位置選擇相應字段即可。
第二種情況，不同的圖層建立不同大小的緩沖區
假設還有其他不同的數據，不僅僅是道路，這些圖層都需要建立緩沖區。
步驟：
1、 找到Buffer工具，右鍵，選擇Batch，打開批處理面板。從該面板上我們可以發現，參數與我們打開Buffer的參數是一樣的，這個時候是不是可以考慮在EXCEL中批量編輯好，然后復制過來呢
2、 在Excel中編輯需要的數據。
3、 將在Excel中編輯的數據復制到Buffer的批處理面板中來。此處需要注意，如果要復制10行數據，需要在批處理面板中先選中10行，右鍵單擊，選擇“paste”。
4、 點擊OK即可。
如果想要每個圖層中每種類型的數據的緩沖區寬度都不一樣，該怎樣處理的?這個留給您來嘗試吧，原理很簡單，就是找到參數位置，寫上對應的字段即可。
第三種情況，Python實現批處理
如果您覺得上面的方法比較麻煩，而且要求也比較嚴格，您可以考慮應用Python來處理。
步驟：
1、 編寫代碼
import arcpy,os
inFCs = arcpy.GetParameterAsText(0)
outWS = arcpy.GetParameterAsText(1)
dist = arcpy.GetParameterAsText(2)
inFCs = inFCs.split(";")
for inFC in inFCs:
fileName =os.path.split(inFC)[1]
arcpy.Buffer_analysis(inFC,outWS + "\\" + fileName, str(dist) + "meter")
上面這段代碼，要求用戶自己設置輸入數據、輸出數據、緩沖區寬度(單位為米)。這里輸出緩沖區數據的名稱和輸入數據的名稱一樣，如果不想要這樣，可以進一步修改代碼。
2、 接下來將該代碼增加到ArcToolbox中，步驟比較簡單，這里不再贅述。
需要注意的地方為最后的參數設置部分，”輸入數據”的“MutiValue”屬性設置為”Yes”。(此部分的參數設置較條條框框較多，需要與你的代碼相互對照)
3、 完成后，工具將會添加到您自己的工具箱中。打開該工具，您會看到界面像普通工具的界面一樣，輸入數據可以設置很多個，但是這個工具所有圖層的緩沖區大小必須一樣。
八、注意
1、解決中文亂碼問題
REM 聲明采用UTF-8編碼
chcp 65001
2、獲取路徑
@echo off echo 當前路徑：%cd% echo 當前盤符：%~d0 echo 當前盤符和路徑：%~dp0 echo 當前批處理全路徑：%~f0 echo 當前盤符和路徑的短文件名格式：%~sdp0 echo 當前CMD默認目錄：%cd% pause九、參考鏈接
1、百度百科：https://baike.baidu.com/item/%E6%89%B9%E5%A4%84%E7%90%86
2、批處理之家：http://www.bathome.net/
總結
- 上一篇： OC5021B 开关降压型 LED 恒流
- 下一篇： JavaScript——onblur事件