包和DLL的對比

使用DLL來為它們的服務器應用程序存放管理窗體會導致DLL擁有自己的Forms.pas文件副本。這將會引起一個不可思議的錯誤，該錯誤與Windows的窗口句柄處理有關。Windows窗口句柄處理產生于DLL中——當DLL被卸載時，窗口句柄卻不能被操作系統解除參照。下一個穿過隊列被發往頂層窗口的消息會導致應用程序出錯，這樣操作系統就會因為應用程序處于非法狀態而將它關閉。使用包代替DLL可以克服這個問題，因為包引用了主應用程序的Forms.pas副本，因此消息隊列能夠成功地傳到應用程序。

文件擴展名

文件類型

描述

.dbk

包源文件

當調用包編譯器時創建.dpk文件。正如大家所想到的，這有點類似于Delphi項目創建一個.dpr文件

.dcp

運行期/設計期包標識文件

這是已編譯的包，它包含了包及其單元的標識信息。另外，還有Delphi IDE所需的報頭信息

.dcu

編譯過的單元

一個包含在某個包中的已編譯單元，包中的每一個單元都一個相應的.dcu文件

.bpl

運行期/設計期

這是運行期包或設計期包的庫類型的包文件，相當于Windows中的DLL。對于一個運行期包，應該和應用程序（如果它們已經被激活）一起發布這個文件。假如這個文件代表的是一個設計期包，應該和運行期包一起發布給使用它們寫程序的程序員。注意如果所發布的不是源代碼，就必須發布相應的.dcp文件

包文件

位置

運行期包（*.bpl）

運行期包應該被放到Windows\system\目錄下（Windows95/98）或WinNT\System32\目錄下（Windows NT/2000）

設計期包（*.bpl）

因為從不同的賣主得到幾個包是可能的，所以應該把設計期包放在公共的目錄下，以便于管理。比如，在\Delphi 6\目錄下創建\PKG目錄，可以把設計期包放在這里

包標志文件（*.dcp）

可以把包標識文件放在和設計期包文件（*.bpl）相同的地方

編譯單元（*.dcu）

假如正在發布沒有源代碼的包，必須同時發布已編譯的單元，我們推薦把DCU文件存放在類似\Delphi 6\Lib的目錄下，不要把自己的DCU文件和第三方賣主的DCU文件放在一起。比如，我們可以創建目錄\Delphi 6\3PrtyLib來存放第三方組件的*.dcu。必須要把這個目錄包括到搜索路徑中去。

Unit DDGReg

Interface

Procedure Register;

Implementation

uses

?? Classes, ExptIntf, DsgnIntf, TrayIcon, AppBars, ABExpt, Worthless, RunBtn, PwDlg, Planets, LbTab, HalfMin, DDGClock, ExMemo, MenView, Marquee, PlanetPE, RunBtnPE, CompEdit, DefProp, Wavez, WavezEd, LnchPad, LPadPE, Cards, ButtonEdit, Planet, DrwPnel;

Procedure Register;

begin

?????? //Register the components

? RegisterComponents('DDG',[TddgTrayNotifyIcon, TddDigitalClock, TddgHalfMinute, TddgButtonEdit, TddgExtendedMemo,????????? TddgTabListbox, TddgRunButton, TddgLaunchPadm, TddgMenView, TddgMarquee, TddgWaveFile, TddgCard, TddgPasswordDialog, TddgPlanet, TddgPlanets, TddgWorthLess, TddgDrawPanel, TComponentEditorSample, TDefinePropTest]);

? //Register any property editor

? RegisterPropertyEditor(TypeInfo(TRunButton),TddgLaunchPad,'',TRunButtonProperty);

? RegisterpropertyEditor(TypeInfo(TWaveFileString), TddgWaveFile, 'WaveName',TWaveFileStringProperty);

? RegisterpropertyEditor(TddgWaveFile, TWaveEditor);

? RegisterpropertyEditor(TComponentEdtiorSample, TSampleEditor);

? RegisterpropertyEditor(TypeInfo(TPlanetName), TddgPlanet, 'PlanetName', TPlanetNameProperty);

? RegisterpropertyEditor(TypeInfo(TCommandLine), TddgRunButton,'', TCommandLineProperty);

? RegisterCustomModule(TAppBar, TCustomModule);

? RegisterLibraryExpert(TAappBarExpert.Create);

end;

end.

件安全

即使某個人只有我們的運行期包，也能注冊我們的組件。他可以調用他自己的注冊單元來注冊我們的組件。然后他把這個單元添加到一個單獨的包中，此包的requires子句下有我們的運行期包。在他把這個新包安裝到Delphi IDE后，組件將出現在組件面板中。然而，他不可能用我們的組件來編譯任何應用程序，因為在組件單元中沒有必需的*.dcu文件

指示符

含義

{$G} or {IMPORTEDDATA OFF}

如果不想使單元被打包，而是想直接和應用程序相連接，就要使用這個指示符。把它和{$WEAKPACKAGEUNIT}比較一下，{$WEAKPACKAGEUNIT}允許一個包中包括單元，它的代碼是靜態的和應用程序相連接

{$DENYPACKAGEUNIT}

含義同{$G}

{$WEAKPACKAGEUNIT}

參見“關于{$WEAKPACKAGEUNIT}的更多信息”小節

指示符

含義

{$DESIGNONLY ON}

把包作為設計期包編譯

{$RUNONLY ON}

把包作為運行期包編譯

{$IMPLICITBUILD OFF}

防止包被重編譯。當不經常改變包時使用這個選項

Initialization

? RegisterClass(TCF2Form);

Finalization

? UnRegisterClass(TCF2Form);

unit MainFrm;

interface

uses

? Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,

? StdCtrls, ExtCtrls, ChildFrm, Menus;

const

? { Child form registration location in the Windows Registry. }

? cAddInIniFile? = 'AddIn.ini';

? cCFRegSection? = 'ChildForms';? // Module initialization data section

? FMainCaption?? = 'Delphi 6 Developer''s Guide Child Form Demo';

type

? TChildFormClass = class of TChildForm;

? TMainForm = class(TForm)

??? pnlMain: TPanel;

??? Splitter1: TSplitter;

??? pnlParent: TPanel;

??? mmMain: TMainMenu;

??? mmiFile: TMenuItem;

??? mmiExit: TMenuItem;

??? mmiHelp: TMenuItem;

??? mmiForms: TMenuItem;

??? procedure mmiExitClick(Sender: TObject);

??? procedure FormCreate(Sender: TObject);

??? procedure FormDestroy(Sender: TObject);

? private

??? // reference to the child form.

??? FChildForm: TChildForm;

??? // a list of available child forms used to build a menu.

??? FChildFormList: TStringList;

??? // Index to the Close Form menu which shifts position.

??? FCloseFormIndex: Integer;

??? // Handle to the currently loaded package.

??? FCurrentModuleHandle: HModule;

??? // method to create menus for available child forms.

??? procedure CreateChildFormMenus;

??? // Handler to load a child form and its package.

??? procedure LoadChildFormOnClick(Sender: TObject);

??? // Handler to unload a child form and its package.

??? procedure CloseFormOnClick(Sender: TObject);

??? // Method to retrieve the classname for a TChildForm descendant

??? function GetChildFormClassName(const AModuleName: String): String;

? public

??? { Public declarations }

? end;

var

? MainForm: TMainForm;

implementation

uses IniFiles;

{$R *.DFM}

function RemoveExt(const AFileName: String): String;

{ Helper function to removes the extension from a file name. }

begin

? if Pos('.', AFileName) <> 0 then

??? Result := Copy(AFileName, 1, Pos('.', AFileName)-1)

? else

??? Result := AFileName;

end;

procedure TMainForm.mmiExitClick(Sender: TObject);

begin

? Close;

end;

procedure TMainForm.FormCreate(Sender: TObject);

begin

? FChildFormList := TStringList.Create;

? CreateChildFormMenus;

end;

procedure TMainForm.FormDestroy(Sender: TObject);

begin

? FChildFormList.Free;

? // Unload any loaded child forms.

? if FCurrentModuleHandle <> 0 then

??? CloseFormOnClick(nil);

end;

procedure TMainForm.CreateChildFormMenus;

{ All available child forms are registered in the Windows Registry.

? Here, we use this information to creates menu items for loading each of the

? child forms. }

var

? IniFile: TIniFile;

? MenuItem: TMenuItem;

? i: integer;

begin

? inherited;

? { Retrieve a list of all child forms and build a menu based on the

??? entries in the registry. }

? IniFile := TIniFile.Create(ExtractFilePath(Application.ExeName)+cAddInIniFile);

? try

??? IniFile.ReadSectionValues(cCFRegSection, FChildFormList);

? finally

??? IniFile.Free;

? end;

? { Add Menu items for each module. NOTE THE mmMain.AutoHotKeys property must

??? bet set to maAutomatic }

? for i := 0 to FChildFormList.Count - 1 do

? begin

??? MenuItem := TMenuItem.Create(mmMain);

??? MenuItem.Caption := FChildFormList.Names[i];

??? MenuItem.OnClick := LoadChildFormOnClick;

??? mmiForms.Add(MenuItem);

? end;

? // Create Separator

? MenuItem := TMenuItem.Create(mmMain);

? MenuItem.Caption := '-';

? mmiForms.Add(MenuItem);

? // Create Close Module menu item

? MenuItem := TMenuItem.Create(mmMain);

? MenuItem.Caption := '&Close Form';

? MenuItem.OnClick := CloseFormOnClick;

? MenuItem.Enabled := False;

? mmiForms.Add(MenuItem);

? { Save a reference to the index of the menu item required to

??? close a child form. This will be referred to in another method. }

? FCloseFormIndex := MenuItem.MenuIndex;

end;

procedure TMainForm.LoadChildFormOnClick(Sender: TObject);

var

? ChildFormClassName: String;

? ChildFormClass: TChildFormClass;

? ChildFormName: String;

? ChildFormPackage: String;

begin

? // The menu caption represents the module name.

? ChildFormName := (Sender as TMenuItem).Caption;

? // Get the actual Package file name.

? ChildFormPackage := FChildFormList.Values[ChildFormName];

? // Unload any previously loaded packages.

? if FCurrentModuleHandle <> 0 then

??? CloseFormOnClick(nil);

? try

??? // Load the specified package

??? FCurrentModuleHandle := LoadPackage(ChildFormPackage);

??? // Return the classname that needs to be created

??? ChildFormClassName := GetChildFormClassName(ChildFormPackage);

??? { Create an instance of the class using the FindClass() procedure. Note,

????? this requires that the class already be registered with the streaming

????? system using RegisterClass().? This is done in the child form

????? initialization section for each child form package. }

??? ChildFormClass := TChildFormClass(FindClass(ChildFormClassName));

??? FChildForm := ChildFormClass.Create(self, pnlParent);

??? Caption := FChildForm.GetCaption;

??? { Merge child form menus with the main menu }

??? if FChildForm.GetMainMenu <> nil then

????? mmMain.Merge(FChildForm.GetMainMenu);

??? FChildForm.Show;

??? mmiForms[FCloseFormIndex].Enabled := True;

? except

??? on E: Exception do

??? begin

????? CloseFormOnClick(nil);

????? raise;

??? end;

? end;

end;

function TMainForm.GetChildFormClassName(const AModuleName: String): String;

{ The Actual class name of the TChildForm implementation resides in the

? registry. This method retrieves that class name. }

var

? IniFile: TIniFile;

begin

? IniFile := TIniFile.Create(ExtractFilePath(Application.ExeName)+cAddInIniFile);

? try

??? Result := IniFile.ReadString(RemoveExt(AModuleName), 'ClassName',

????? EmptyStr);

? finally

??? IniFile.Free;

? end;

end;

procedure TMainForm.CloseFormOnClick(Sender: TObject);

begin

? if FCurrentModuleHandle <> 0 then

? begin

??? if FChildForm <> nil then

??? begin

????? FChildForm.Free;

????? FChildForm := nil;

??? end;

??? // Unregister any classes provided by the module

??? UnRegisterModuleClasses(FCurrentModuleHandle);

??? // Unload the child form package

??? UnloadPackage(FCurrentModuleHandle);

??? FCurrentModuleHandle := 0;

??? mmiForms[FCloseFormIndex].Enabled := False;

??? Caption := FMainCaption;

? end;

end;

end.

ChildFormClass := TchildFormClass(FindClass(ChildFormClassName));

FchildForm := ChildFormClass.Create(self, pnlParent);

說明：類引用不過是內存中的某個區域，其中包含了相關類的信息，這和類的類型定義是一回事情。當用VCL流系統或RegisterClass()函數注冊這個類時，類引用就會進入內存，FindClass()函數查找內存區域，定位某個指定類名的類，并返回一個指向那個位置的指針，這不同于類實例。類實例是創建于調用構造函數時。

unit FunkFrm;

interface

uses

? Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,

? Dialogs, StdCtrls;

type

? TFunkForm = class(TForm)

??? Label1: TLabel;

??? Button1: TButton;

? private

??? { Private declarations }

? public

??? { Public declarations }

? end;

// Declare the package functions using the StdCall calling convention

procedure FunkForm; stdcall;

function AddEm(Op1, Op2: Integer): Integer; stdcall;

// Export the functions.

exports

? FunkForm,

? AddEm;

implementation

{$R *.dfm}

procedure FunkForm;

var

? FunkForm: TFunkForm;

begin

? FunkForm := TFunkForm.Create(Application);

? try

??? FunkForm.ShowModal;

? finally

??? FunkForm.Free;

? end;

end;

function AddEm(Op1, Op2: Integer): Integer;

begin

? Result := Op1+Op2;

end;

end.

unit MainFrm;

interface

uses

? Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,

? Dialogs, StdCtrls, Mask;

const

? cFunkForm = 'FunkForm';

? cAddEm??? = 'AddEm';

type

? TForm1 = class(TForm)

??? btnPkgForm: TButton;

??? meOp1: TMaskEdit;

??? meOp2: TMaskEdit;

??? btnAdd: TButton;

??? lblPlus: TLabel;

??? lblEquals: TLabel;

??? lblResult: TLabel;

??? procedure btnAddClick(Sender: TObject);

??? procedure btnPkgFormClick(Sender: TObject);

? private

??? { Private declarations }

? public

??? { Public declarations }

? end;

? // Defined the method signatures

? TAddEmProc = function(Op1, Op2: Integer): integer; stdcall;

? TFunkFormProc = procedure; stdcall;

var

? Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.btnAddClick(Sender: TObject);

var

? PackageModule: THandle;

? AddEmProc: TAddEmProc;

? Rslt: Integer;

? Op1, Op2: integer;

begin

? PackageModule := LoadPackage('ddgPackFunk.bpl');

? try

??? @AddEmProc := GetProcAddress(PackageModule, PChar(cAddEm));

??? if not (@AddEmProc = nil) then

??? begin

????? Op1 := StrToInt(meOp1.Text);

????? Op2 := StrToInt(meOp2.Text);

????? Rslt := AddEmProc(Op1, Op2);

????? lblResult.Caption := IntToStr(Rslt);

??? end;

? finally

??? UnloadPackage(PackageModule);

? end;

end;

procedure TForm1.btnPkgFormClick(Sender: TObject);

var

? PackageModule: THandle;

? FunkFormProc: TFunkFormProc;

begin

? PackageModule := LoadPackage('ddgPackFunk.bpl');

? try

??? @FunkFormProc := GetProcAddress(PackageModule, PChar(cFunkForm));

??? if not (@FunkFormProc = nil) then

????? FunkFormProc;

? finally

??? UnloadPackage(PackageModule);

? end;

end;

end.

unit MainFrm;

interface

uses

? Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,

? Dialogs, StdCtrls, ComCtrls, DBXpress, DB, SqlExpr, DBTables;

type

? TForm1 = class(TForm)

??? Button1: TButton;

??? TreeView1: TTreeView;

??? Table1: TTable;

??? SQLConnection1: TSQLConnection;

??? procedure Button1Click(Sender: TObject);

? private

??? { Private declarations }

? public

??? { Public declarations }

? end;

var

? Form1: TForm1;

implementation

{$R *.dfm}

type

? TNodeHolder = class

??? ContainsNode: TTreeNode;

??? RequiresNode: TTreeNode;

? end;

procedure RealizeLength(var S: string);

begin

? SetLength(S, StrLen(PChar(S)));

end;

procedure PackageInfoProc(const Name: string; NameType:

? TNameType; Flags: Byte; Param: Pointer);

var

? NodeHolder: TNodeHolder;

? TempStr: String;

begin

? with Form1.TreeView1.Items do

? begin

??? TempStr := EmptyStr;

??? if (Flags and ufMainUnit) <> 0 then

????? TempStr := 'Main unit'

??? else if (Flags and ufPackageUnit) <> 0 then

????? TempStr := 'Package unit' else

??? if (Flags and ufWeakUnit) <> 0 then

????? TempStr := 'Weak unit';

??? if TempStr <> EmptyStr then

????? TempStr := Format(' (%s)', [TempStr]);

??? NodeHolder := TNodeHolder(Param);

??? case NameType of

????? ntContainsUnit: AddChild(NodeHolder.ContainsNode,

??????? Format('%s %s', [Name,TempStr]));

????? ntRequiresPackage: AddChild(NodeHolder.RequiresNode, Name);

??? end; // case

? end;

end;

function EnumModuleProc(HInstance: integer; Data: Pointer): Boolean;

var

? ModFileName: String;

? ModNode: TTreeNode;

? ContainsNode: TTreeNode;

? RequiresNode: TTreeNode;

? ModDesc: String;

? Flags: Integer;

? NodeHolder: TNodeHolder;

begin

? with Form1.TreeView1 do

? begin

??? SetLength(ModFileName, 255);

??? GetModuleFileName(HInstance, PChar(ModFileName), 255);

??? RealizeLength(ModFileName);

??? ModNode := Items.Add(nil, ModFileName);

??? ModDesc := GetPackageDescription(PChar(ModFileName));

??? ContainsNode := Items.AddChild(ModNode, 'Contains');

??? RequiresNode := Items.Addchild(ModNode, 'Requires');

??? if ModDesc <> EmptyStr then

??? begin

????? NodeHolder := TNodeHolder.Create;

????? try

??????? NodeHolder.ContainsNode := ContainsNode;

??????? NodeHolder.RequiresNode := RequiresNode;

??????? GetPackageInfo(HInstance, NodeHolder, Flags, PackageInfoProc);

????? finally

??????? NodeHolder.Free;

????? end;

????? Items.AddChild(ModNode, ModDesc);

????? if Flags and pfDesignOnly = pfDesignOnly then

??????? Items.AddChild(ModNode, 'Design-time package');

????? if Flags and pfRunOnly = pfRunOnly then

??????? Items.AddChild (ModNode, 'Run-time package');

??? end;

? end;

? Result := True;

end;

procedure TForm1.Button1Click(Sender: TObject);

begin

? EnumModules(EnumModuleProc, nil);

end;

end.