最近這幾個(gè)月，XLOOKUP震驚了Excel界，傳言三頭六臂無所不能，一個(gè)人把LOOKUP全家兄弟姐妹的活都給搶了。最開始我是不以為意的，但是相關(guān)的信息越來越多，我終于忍不住，今天去買了一套o(hù)ffice365，發(fā)現(xiàn)還是沒有，查了消息才知道需要加入office預(yù)覽體驗(yàn)計(jì)劃，又折騰了半天，終于XLOOKUP出現(xiàn)在我的函數(shù)列表里，懷著激動(dòng)的心情，開始寫這篇文章。

先放一個(gè)總結(jié)，就是：艾瑪！真香！

但是，香是香了，可是大多數(shù)使用非365版的office的朋友暫時(shí)還用不上XLOOKUP，活還是要干的，咋辦？在這里我整理了一些XLOOKUP函數(shù)的功能以及通過其他函數(shù)實(shí)現(xiàn)的辦法，正好可以以XLOOKUP為線索，系統(tǒng)的講一下LOOKUP家族的常見玩法。

本著喜新厭舊的性格，先介紹一下新人

=XLOOKUP(lookup_value,lookup_array,return_array,[match_mode],[search_mode],[if_not_found])

XLOOKUP函數(shù)一共6個(gè)參數(shù)，前3個(gè)為必填參數(shù)，后3個(gè)選填參數(shù)，一般默認(rèn)值時(shí)可以省略。

lookup_value：查詢值

lookup_array：查詢區(qū)域

return_array：返回值區(qū)域

match_mode：匹配方式。有4個(gè)值可以選：0/省略，精確匹配；-1，精確匹配或下一個(gè)較小項(xiàng)；1，精確匹配或下一個(gè)較大項(xiàng)；2，通配符匹配。

search_mode：查詢方式。1，正序查詢，從上到下，類似于vlookup的玩法；-1，倒序查詢從下往上，類似于lookup的玩法，2和-2沒玩過，是二進(jìn)制文件的正序以及倒序查詢。

if_not_found：查詢不到的返回值。看到這里，我才知道，失業(yè)的不光是VLOOKUP，IFERROR和IFNA也跟著失業(yè)了，以往VLOOKUP等函數(shù)查詢不到結(jié)果的時(shí)候，會返回錯(cuò)誤值#N/A，我習(xí)慣用IFERROR屏蔽錯(cuò)誤值，但是在XLOOKUP這里，只需要把IFERROR里面第二參數(shù)填的內(nèi)容填在XLOOKUP的第六參數(shù)里面就可以了，如果不填，查詢不到依舊會返回#N/A。這感覺就像加多寶和王老吉打架，把和其正給打死了，這冤不冤啊！

下面來繼續(xù)講講這一家子的玩法

一、單條件查找

這是VLOOKUP最擅長干的活了，但是XLOOKUP又有什么特別的呢？

=XLOOKUP(H9,$H$2:$H$5,$K$2:$K$5,0,1,"找不到")

這里為了演示，我把6個(gè)參數(shù)全部填滿了，但其實(shí)第四第五參數(shù)是可以省略的：

=XLOOKUP(H9,$H$2:$H$5,$K$2:$K$5,,,"找不到")

如果不需要填第六參數(shù)：

=XLOOKUP(H9,$H$2:$H$5,$K$2:$K$5)

如果不使用XLOOKUP，那么使用VLOOKUP，LOOKUP，INDEX+MATCH都可以實(shí)現(xiàn)，這里介紹最常用的VLOOKUP用法：

=IFERROR(VLOOKUP(H15,$H$2:$K$5,4,0),"找不到")

可以看到，為了實(shí)現(xiàn)和XLOOKUP第六參數(shù)一樣的功能，這里用到了IFERROR，也可以用IFNA。

LOOKUP玩法：

=LOOKUP(0,1/(H9=$H$2:$H$5),$K$2:$K$5)

在這里看，XLOOKUP和LOOKUP家族其他成員相比，并沒有什么優(yōu)勢，反而好像更復(fù)雜一些，6個(gè)參數(shù)看著都頭暈，要他干嘛呢？下面就要展示真正的技術(shù)了，如果要查詢的不是一列數(shù)據(jù)，而是要返回多列數(shù)據(jù)把后面的1-12月都填滿該怎么辦呢？

二、查詢返回多列

接著上面的說，如果返回多列數(shù)據(jù)，XLOOKUP終于要體現(xiàn)出優(yōu)越性了。

=XLOOKUP(H9,$H$2:$H$5,$K$2:$V$5)

從圖上可以看到，點(diǎn)擊填充數(shù)據(jù)的單元格的時(shí)候，后面的單元格也一起框出來了，這就是office的新功能，動(dòng)態(tài)數(shù)組溢出，返回值為單個(gè)時(shí)和之前一樣，返回值為數(shù)組時(shí)，自動(dòng)溢出向右或者向下填充。公式只在第一個(gè)單元格里面。

然而這個(gè)活沒有XLOOKUP怎么干呢？

方法一：VLOOKUP+MATCH

=VLOOKUP($H14,$H$2:$V$5,MATCH(K$13,$H$1:$V$1,),)

這里第三參數(shù)使用MATCH函數(shù)生成，如果確定返回?cái)?shù)據(jù)和查詢數(shù)據(jù)表頭完全一致，那么第三參數(shù)可以直接改為COLUMN(D:D)：

=VLOOKUP($H14,$H$2:$V$5,COLUMN(D:D),)

方法二：有沒有更簡單的辦法？LOOKUP來了：

=LOOKUP(1,0/($H$2:$H$5=$H14),K$2:K$5)

這里的用法與VLOOKUO+COLUMN一樣，也是表頭完全一致的情況下才可以用關(guān)鍵是K$2:K$5使用行絕對引用列相對引用。

可以看出，到這一步XLOOKUP的優(yōu)越性就體現(xiàn)出來了，語法簡單，不需要嵌套其他函數(shù)，但是如果沒有XLOOKUP，LOOKUP的語法也比較簡單。

三、多條件查詢

日常當(dāng)中經(jīng)常會遇到多條件查詢的情況，以往需要使用VLOOKUP+IF數(shù)組公式來實(shí)現(xiàn)，或者使用LOOKUP。而使用XLOOKUP就簡單多了：

=XLOOKUP(I9&J9,$I$2:$I$5&$J$2:$J$5,$K$2:$V$5)

使用VLOOKUP：

=VLOOKUP($I14&$J14,IF({1,0},$I$2:$I$5&$J$2:$J$5,K$2:K$5),2,)

使用LOOKUP：

=LOOKUP(1,0/(($I14=$I$2:$I$5)*($J14=$J$2:$J$5)),K$2:K$5)

這是LOOKUP常用的多條件查詢的使用方法，相乘表示且的關(guān)系，等于AND，相加表示或的關(guān)系，等于OR的用法。

可以看出，對于多條件查詢，VLOOKUP和LOOKUP雖然可以實(shí)現(xiàn)，但是語法嵌套關(guān)系比XLOOKUP復(fù)雜得多，而且邏輯關(guān)系，相對引用和絕對引用的使用，可能不熟悉的朋友會很頭疼，但是如果要兩個(gè)條件滿足其一即可的情況下，LOOKUP就比XLOOKUP和VLOOKUP簡單得多了。

四、橫向查詢

在LOOKUP家族中，HLOOKUP像是清高孤傲的大家閨秀，一般很少露面，但是她的工作，除了INDEX+MATCH能摻和，一般沒人搶飯碗，INDEX+MATCH畢竟寫起來復(fù)雜，HLOOKUP的工作還是很穩(wěn)定。但是這次XLOOKUP的到來，連HLOOKUP的飯碗也被搶了。

通過月，查詢對于行的值：

=XLOOKUP(K$8:V$8,K$1:V$1,$K3:$V3)

這里也是利用動(dòng)態(tài)數(shù)組溢出，把K9單元格的內(nèi)容向右溢出

HLOOKUP實(shí)現(xiàn)方法：

=HLOOKUP(K$13,$K$1:$V$5,ROW(3:3),)

第三參數(shù)使用ROW函數(shù)產(chǎn)生，和前面VLOOKUP里面用的COLUMN一個(gè)道理。看起來，還是XLOOKUP使用起來簡單。如果結(jié)合多條件查詢，XLOOKUP函數(shù)的優(yōu)勢更明顯。

五、模糊查詢，根據(jù)分?jǐn)?shù)判定等級

=XLOOKUP(B2:B30,H2:H6,J2:J6,-1,)

這里，第四參數(shù)-1，表示從小到大升序匹配，用了XLOOKUP動(dòng)態(tài)數(shù)組自動(dòng)溢出功能以后，簡直不要太爽！爽到停不下來！再也不用擔(dān)心相對引用和絕對引用搞錯(cuò)了！

如果使用VLOOKUP模糊匹配，也可以實(shí)現(xiàn)：

=VLOOKUP(B2,$H$2:$J$6,3,1)

VLOOKUP當(dāng)中，是否絕對引用就很重要了，第四參數(shù)1表示模糊匹配，VLOOKUP模糊匹配需要查詢數(shù)據(jù)升序排列

還可以用LOOKUP：

=LOOKUP(B2,$H$2:$H$6,$J$2:$J$6)

可以看出LOOKUP語法也比較簡單

以上查詢數(shù)據(jù)都是升序排列，如果是降序，那么就會出錯(cuò)：

這個(gè)時(shí)候，XLOOKUP只需要把第四參數(shù)改為1：

=XLOOKUP(B2:B30,H2:H6,J2:J6,1,)

其他兩位，就很難搞定了。

到這里，LOOKUP家族的多數(shù)常用功能就講的差不多了，可以看到，XLOOKUP可以算是把全家的飯碗都給搶了，而且銜著金鑰匙出生的XLOOKUP憑借動(dòng)態(tài)數(shù)組的加成，大大簡化了語法以及對絕對引用的要求。總結(jié)起來就兩個(gè)字：

真香！！！！

最后，如果你有其他思路，歡迎和我分享，如有Excel使用的問題需要解決，也歡迎留言或者私信交流，

我會的，我會盡量回復(fù)大家；

我不會的，我去學(xué)會后再分享給大家；

我學(xué)不會的，我盡量推薦大神來回答。

我就是個(gè)菜鳥，也希望能幫到在這條路上更多的你，不寫公眾號，不引流，不賣課程，單純的交流學(xué)習(xí)。

——————————分割線———————————

收藏是贊同的五倍，各位，點(diǎn)個(gè)贊再走啊！

總結(jié)

以上是生活随笔為你收集整理的endpointimpl怎么填参数_这是一篇VLOOKUP函数家族主要用法的合集，XLOOKUP来了！真香！但是，没有office365吃不着怎么办？...的全部內(nèi)容，希望文章能夠幫你解決所遇到的問題。

如果覺得生活随笔網(wǎng)站內(nèi)容還不錯(cuò)，歡迎將生活随笔推薦給好友。